Version bump, add icu USE-flag in sync with gnustep-base

(Portage version: 2.2.19/cvs/Linux x86_64, signed Manifest commit with key 00F7AB331B0F097F)

2 files changed, 63 insertions, 1 deletions

diff --git a/gnustep-base/gnustep-gui/ChangeLog b/gnustep-base/gnustep-gui/ChangeLog
index b63de63c7eed..e793fc1241d2 100644
--- a/gnustep-base/gnustep-gui/ChangeLog
+++ b/gnustep-base/gnustep-gui/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for gnustep-base/gnustep-gui
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-gui/ChangeLog,v 1.106 2015/04/21 19:12:12 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-gui/ChangeLog,v 1.107 2015/05/18 14:57:02 voyageur Exp $
+
+*gnustep-gui-0.24.1 (18 May 2015)
+
+  18 May 2015; Bernard Cafarelli <voyageur@gentoo.org>
+  +gnustep-gui-0.24.1.ebuild:
+  Version bump, add icu USE-flag in sync with gnustep-base
 
   21 Apr 2015; Pacho Ramos <pacho@gentoo.org> gnustep-gui-0.24.0.ebuild:
   ppc stable wrt bug #508626
diff --git a/gnustep-base/gnustep-gui/gnustep-gui-0.24.1.ebuild b/gnustep-base/gnustep-gui/gnustep-gui-0.24.1.ebuild
new file mode 100644
index 000000000000..b1d428a72cf4
--- /dev/null
+++ b/gnustep-base/gnustep-gui/gnustep-gui-0.24.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-gui/gnustep-gui-0.24.1.ebuild,v 1.1 2015/05/18 14:57:02 voyageur Exp $
+
+EAPI=5
+inherit gnustep-base multilib
+
+DESCRIPTION="Library of GUI classes written in Obj-C"
+HOMEPAGE="http://www.gnustep.org/"
+SRC_URI="ftp://ftp.gnustep.org/pub/gnustep/core/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="cups gif icu jpeg png speech"
+
+DEPEND="${GNUSTEP_CORE_DEPEND}
+	app-text/aspell
+	>=gnustep-base/gnustep-base-1.24.6[icu?]
+	media-libs/audiofile
+	>=media-libs/tiff-3:=
+	x11-libs/libXt
+	cups? ( >=net-print/cups-1.7.4:= )
+	gif? ( >=media-libs/giflib-4.1:= )
+	icu? ( dev-libs/icu:= )
+	jpeg? ( virtual/jpeg:= )
+	png? ( >=media-libs/libpng-1.2:= )
+	speech? ( app-accessibility/flite )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	gnustep-base_src_prepare
+
+	# remove hardcoded -g -Werror, bug #378179
+	sed -i -e 's/-g -Werror//' \
+		Tools/say/GNUmakefile \
+		Tools/speech/GNUmakefile \
+		|| die
+}
+
+src_configure() {
+	egnustep_env
+
+	local myconf=
+	use gif && myconf="--disable-ungif --enable-libgif"
+
+	econf \
+		$(use_enable cups) \
+		$(use_enable icu) \
+		$(use_enable jpeg) \
+		$(use_enable png) \
+		$(use_enable speech) \
+		--with-tiff-include="${EPREFIX}"/usr/include \
+		--with-tiff-library="${EPREFIX}"/usr/$(get_libdir) \
+		${myconf}
+}