version bump

(Portage version: 2.1.1-r2)

3 files changed, 135 insertions, 1 deletions

diff --git a/games-fps/nexuiz/ChangeLog b/games-fps/nexuiz/ChangeLog
index c75a8c3f5e3f..45643248d365 100644
--- a/games-fps/nexuiz/ChangeLog
+++ b/games-fps/nexuiz/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-fps/nexuiz
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/ChangeLog,v 1.19 2007/01/03 16:02:26 nyhm Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/ChangeLog,v 1.20 2007/01/28 04:40:14 mr_bones_ Exp $
+
+*nexuiz-2.2.3 (28 Jan 2007)
+
+  28 Jan 2007; Michael Sterrett <mr_bones_@gentoo.org> +nexuiz-2.2.3.ebuild:
+  version bump
 
 *nexuiz-2.2.2 (03 Jan 2007)
 
diff --git a/games-fps/nexuiz/files/digest-nexuiz-2.2.3 b/games-fps/nexuiz/files/digest-nexuiz-2.2.3
new file mode 100644
index 000000000000..03721bde4db0
--- /dev/null
+++ b/games-fps/nexuiz/files/digest-nexuiz-2.2.3
@@ -0,0 +1,6 @@
+MD5 8e15713720964a3223a34ee00700a494 nexmappack.zip 120018513
+RMD160 3197e83f9b41a887924cedc46adec567a6c6959c nexmappack.zip 120018513
+SHA256 59044b6ab393cf8db31cb874b4aec291a489e272f52af9bfd6e7c39a2ffbb78f nexmappack.zip 120018513
+MD5 953fda1555fc1f9ca040bdbb797eb0fd nexuiz-223.zip 199639016
+RMD160 c1cbf7cfca103c2c6e599291339cf4422a1243e9 nexuiz-223.zip 199639016
+SHA256 fef9d5bb3edf56e4db1e5db2d66150b5d3e619870b5d32df9263f70f8120395a nexuiz-223.zip 199639016
diff --git a/games-fps/nexuiz/nexuiz-2.2.3.ebuild b/games-fps/nexuiz/nexuiz-2.2.3.ebuild
new file mode 100644
index 000000000000..e0c6b5ccec56
--- /dev/null
+++ b/games-fps/nexuiz/nexuiz-2.2.3.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/nexuiz-2.2.3.ebuild,v 1.1 2007/01/28 04:40:14 mr_bones_ Exp $
+
+inherit eutils toolchain-funcs games
+
+MY_PN=Nexuiz
+MY_P=${PN}-${PV//./}
+DESCRIPTION="Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
+HOMEPAGE="http://www.nexuiz.com/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.zip
+	mirror://sourceforge/${PN}/nexmappack.zip"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa dedicated opengl sdl"
+
+UIRDEPEND="alsa? ( media-libs/alsa-lib )
+	media-libs/libogg
+	media-libs/libvorbis
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXdmcp
+	x11-libs/libXext
+	x11-libs/libXxf86dga
+	x11-libs/libXxf86vm"
+UIDEPEND="x11-proto/xextproto
+	x11-proto/xf86dgaproto
+	x11-proto/xf86vidmodeproto
+	x11-proto/xproto"
+RDEPEND="media-libs/jpeg
+	net-misc/curl
+	sdl? ( media-libs/libsdl ${UIRDEPEND} )
+	opengl? ( virtual/opengl ${UIRDEPEND} )
+	!dedicated? ( !sdl? ( !opengl? ( virtual/opengl ${UIRDEPEND} ) ) )"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	sdl? ( media-libs/libsdl ${UIDEPEND} )
+	opengl? ( virtual/opengl ${UIDEPEND} )
+	!dedicated? ( !sdl? ( !opengl? ( virtual/opengl ${UIDEPEND} ) ) )"
+
+S=${WORKDIR}/darkplaces
+
+src_unpack() {
+	unpack ${MY_P}.zip
+
+	local f
+	for f in "${MY_PN}"/sources/*.zip ; do
+		unpack ./${f}
+	done
+
+	cd "${WORKDIR}"/${MY_PN}
+	unpack nexmappack.zip
+
+	cd "${S}"
+	# Make the game automatically look in the correct data directory
+	sed -i "s:gamedirname1:\"${PN}\":" fs.c \
+		|| die "sed fs.c failed"
+
+	sed -i makefile.inc \
+		-e "/^CC=/s:gcc:$(tc-getCC):" \
+		-e "s/-O2/${CFLAGS}/" \
+		-e "/-lm/s:$: ${LDFLAGS}:" \
+		-e '/strip/d' \
+		|| die "sed makefile.inc failed"
+
+	# This is the right dir, so that e.g. "darkplaces -game nexuiz" will work
+	sed -i "s:ifdef DP_.*:DP_FS_BASEDIR=${GAMES_DATADIR}/quake1\n&:" makefile \
+		|| die "sed makefile failed"
+
+	if ! use alsa ; then
+		sed -i "/DEFAULT_SNDAPI/s:ALSA:OSS:" makefile \
+			|| die "sed makefile failed"
+	fi
+}
+
+src_compile() {
+	if use opengl || (! use dedicated && ! use sdl) ; then
+		emake cl-${PN} || die "emake cl-${PN} failed"
+	fi
+
+	if use sdl ; then
+		emake sdl-${PN} || die "emake sdl-${PN} failed"
+	fi
+
+	if use dedicated ; then
+		emake sv-${PN} || die "emake sv-${PN} failed"
+	fi
+}
+
+src_install() {
+	if use opengl || use sdl || ! use dedicated ; then
+		newicon darkplaces72x72.png ${PN}.png
+	fi
+
+	if use opengl || (! use dedicated && ! use sdl) ; then
+		dogamesbin ${PN}-glx || die "dogamesbin glx failed"
+		make_desktop_entry ${PN}-glx "Nexuiz (GLX)"
+		dosym "${GAMES_BINDIR}"/{${PN}-glx,${PN}}
+	fi
+
+	if use sdl ; then
+		dogamesbin ${PN}-sdl || die "dogamesbin sdl failed"
+		make_desktop_entry ${PN}-sdl "Nexuiz (SDL)"
+		use opengl || dosym "${GAMES_BINDIR}"/{${PN}-sdl,${PN}}
+	fi
+
+	if use dedicated ; then
+		dogamesbin ${PN}-dedicated || die "dogamesbin dedicated failed"
+	fi
+
+	cd "${WORKDIR}"/${MY_PN}
+	insinto "${GAMES_DATADIR}"/quake1/${PN}
+	doins -r data/* || die "doins data failed"
+
+	dodoc Docs/*.txt
+	dohtml Docs/*.{htm,html}
+	docinto server
+	dodoc Docs/server/*.{cfg,txt}
+
+	prepgamesdirs
+}