Fix bug 272886

(Portage version: 2.2_rc33/cvs/Linux i686)

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-util/devhelp/devhelp-0.23-r1.ebuild b/dev-util/devhelp/devhelp-0.23-r1.ebuild
new file mode 100644
index 000000000000..d570e50b1888
--- /dev/null
+++ b/dev-util/devhelp/devhelp-0.23-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/devhelp/devhelp-0.23-r1.ebuild,v 1.1 2009/06/26 08:17:47 nirbheek Exp $
+
+EAPI="2"
+GCONF_DEBUG="no"
+
+inherit eutils toolchain-funcs gnome2 python
+
+DESCRIPTION="An API documentation browser for GNOME 2"
+HOMEPAGE="http://developer.imendio.com/wiki/Devhelp"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE=""
+
+RDEPEND=">=gnome-base/gconf-2.6
+	>=x11-libs/gtk+-2.10
+	>=dev-libs/glib-2.10
+	>=x11-libs/libwnck-2.10
+	net-libs/webkit-gtk"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	>=dev-util/intltool-0.40
+	>=dev-util/pkgconfig-0.9"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+pkg_setup() {
+	# ICC is crazy, silence warnings (bug #154010)
+	if [[ $(tc-getCC) == "icc" ]] ; then
+		G2CONF="${G2CONF} --with-compile-warnings=no"
+	fi
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# disable pyc compiling
+	rm build/py-compile
+	ln -s $(type -P true) build/py-compile
+
+	epatch "${FILESDIR}/${P}-fix-anchor-links.patch"
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in || die "sed failed"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	python_version
+	python_need_rebuild
+	python_mod_optimize /usr/$(get_libdir)/gedit-2/plugins/devhelp
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup /usr/$(get_libdir)/gedit-2/plugins/devhelp
+}