Version bump (bug 510042). Add multilib support (bug 498010).

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xDADED6B2671CB57D!)

3 files changed, 105 insertions, 2 deletions

diff --git a/dev-qt/qtdemo/ChangeLog b/dev-qt/qtdemo/ChangeLog
index 1b71a8420c20..7998ca189a3c 100644
--- a/dev-qt/qtdemo/ChangeLog
+++ b/dev-qt/qtdemo/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-qt/qtdemo
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtdemo/ChangeLog,v 1.11 2014/01/26 17:55:58 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtdemo/ChangeLog,v 1.12 2014/11/15 02:36:28 pesa Exp $
+
+*qtdemo-4.8.6-r1 (15 Nov 2014)
+
+  15 Nov 2014; Davide Pesavento <pesa@gentoo.org> +qtdemo-4.8.6-r1.ebuild,
+  metadata.xml:
+  Version bump (bug 510042). Add multilib support (bug 498010).
 
   26 Jan 2014; Davide Pesavento <pesa@gentoo.org> -qtdemo-4.8.4.ebuild,
   metadata.xml:
diff --git a/dev-qt/qtdemo/metadata.xml b/dev-qt/qtdemo/metadata.xml
index 4bb5221e23ca..65e4b624d414 100644
--- a/dev-qt/qtdemo/metadata.xml
+++ b/dev-qt/qtdemo/metadata.xml
@@ -1,7 +1,7 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-	<herd>qt</herd> 
+	<herd>qt</herd>
 	<use>
 		<flag name="dbus">Build QtDBus examples and demos</flag>
 		<flag name="declarative">Build QtDeclarative examples and demos</flag>
diff --git a/dev-qt/qtdemo/qtdemo-4.8.6-r1.ebuild b/dev-qt/qtdemo/qtdemo-4.8.6-r1.ebuild
new file mode 100644
index 000000000000..6491f27a544a
--- /dev/null
+++ b/dev-qt/qtdemo/qtdemo-4.8.6-r1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtdemo/qtdemo-4.8.6-r1.ebuild,v 1.1 2014/11/15 02:36:28 pesa Exp $
+
+EAPI=5
+
+inherit qt4-build-multilib
+
+DESCRIPTION="Demonstration module and examples for the Qt toolkit"
+
+if [[ ${QT4_BUILD_TYPE} == live ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x64-macos"
+fi
+
+IUSE="dbus declarative kde multimedia opengl openvg phonon webkit xmlpatterns"
+
+DEPEND="
+	~dev-qt/designer-${PV}[aqua=,debug=,${MULTILIB_USEDEP}]
+	~dev-qt/qtcore-${PV}[aqua=,debug=,${MULTILIB_USEDEP}]
+	~dev-qt/qtgui-${PV}[aqua=,debug=,${MULTILIB_USEDEP}]
+	~dev-qt/qthelp-${PV}[aqua=,debug=,${MULTILIB_USEDEP}]
+	~dev-qt/qtscript-${PV}[aqua=,debug=,${MULTILIB_USEDEP}]
+	~dev-qt/qtsql-${PV}[aqua=,debug=,${MULTILIB_USEDEP}]
+	~dev-qt/qtsvg-${PV}[aqua=,debug=,${MULTILIB_USEDEP}]
+	~dev-qt/qttest-${PV}[aqua=,debug=,${MULTILIB_USEDEP}]
+	dbus? ( ~dev-qt/qtdbus-${PV}[aqua=,debug=,${MULTILIB_USEDEP}] )
+	declarative? ( ~dev-qt/qtdeclarative-${PV}[aqua=,debug=,webkit?,${MULTILIB_USEDEP}] )
+	multimedia? ( ~dev-qt/qtmultimedia-${PV}[aqua=,debug=,${MULTILIB_USEDEP}] )
+	opengl? ( ~dev-qt/qtopengl-${PV}[aqua=,debug=,${MULTILIB_USEDEP}] )
+	openvg? ( ~dev-qt/qtopenvg-${PV}[aqua=,debug=,${MULTILIB_USEDEP}] )
+	phonon? (
+		kde? ( media-libs/phonon[aqua=] )
+		!kde? ( || ( ~dev-qt/qtphonon-${PV}[aqua=,debug=,${MULTILIB_USEDEP}] media-libs/phonon[aqua=] ) )
+	)
+	webkit? ( ~dev-qt/qtwebkit-${PV}[aqua=,debug=,${MULTILIB_USEDEP}] )
+	xmlpatterns? ( ~dev-qt/qtxmlpatterns-${PV}[aqua=,debug=,${MULTILIB_USEDEP}] )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.6-plugandpaint.patch"
+)
+
+QT4_TARGET_DIRECTORIES="
+	demos
+	examples"
+
+src_prepare() {
+	qt4-build-multilib_src_prepare
+
+	# Array mapping USE flags to subdirs
+	local flags_subdirs_map=(
+		'dbus'
+		'declarative:declarative'
+		'multimedia:spectrum'
+		'opengl:boxes|glhypnotizer'
+		'openvg'
+		'phonon:mediaplayer'
+		'webkit:browser'
+		'xmlpatterns'
+	)
+
+	# Disable unwanted examples/demos
+	for flag in "${flags_subdirs_map[@]}"; do
+		if ! use ${flag%:*}; then
+			einfo "Disabling ${flag%:*} examples"
+			sed -i -e "/SUBDIRS += ${flag%:*}/d" \
+				examples/examples.pro || die
+
+			if [[ ${flag} == *:* ]]; then
+				einfo "Disabling ${flag%:*} demos"
+				sed -i -re "/SUBDIRS \+= demos_(${flag#*:})/d" \
+					demos/demos.pro || die
+			fi
+		fi
+	done
+
+	# Remove bogus dependency on qt3support (bug 510042)
+	sed -i -e 's/contains(QT_CONFIG, qt3support)://' \
+		examples/graphicsview/graphicsview.pro || die
+}
+
+multilib_src_configure() {
+	local myconf=(
+		$(qt_use dbus)
+		$(qt_use declarative)
+		$(qt_use multimedia) -no-audio-backend
+		$(qt_use opengl)
+		$(qt_use openvg)
+		$(qt_use phonon) -no-phonon-backend
+		$(qt_use webkit)
+		$(qt_use xmlpatterns)
+	)
+	qt4_multilib_src_configure
+}