Convert to python-r1.eclass. Fixes bug #531146. With thanks to Ian Delaney and Michał Górny.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0x4FDF9CFD2FAC514E!)

2 files changed, 91 insertions, 2 deletions

diff --git a/dev-python/pyside-tools/ChangeLog b/dev-python/pyside-tools/ChangeLog
index 4b3b7d48c6d2..48b67c8d3f45 100644
--- a/dev-python/pyside-tools/ChangeLog
+++ b/dev-python/pyside-tools/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/pyside-tools
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside-tools/ChangeLog,v 1.30 2013/12/26 02:00:56 pesa Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside-tools/ChangeLog,v 1.31 2015/03/23 10:11:42 yngwin Exp $
+
+*pyside-tools-0.2.15-r1 (23 Mar 2015)
+
+  23 Mar 2015; Ben de Groot <yngwin@gentoo.org> +pyside-tools-0.2.15-r1.ebuild:
+  Convert to python-r1.eclass. Fixes bug #531146. With thanks to Ian Delaney and
+  Michał Górny.
 
   26 Dec 2013; Davide Pesavento <pesa@gentoo.org> pyside-tools-0.2.15.ebuild:
   Unrestrict python 3.3
diff --git a/dev-python/pyside-tools/pyside-tools-0.2.15-r1.ebuild b/dev-python/pyside-tools/pyside-tools-0.2.15-r1.ebuild
new file mode 100644
index 000000000000..b4b663a8da82
--- /dev/null
+++ b/dev-python/pyside-tools/pyside-tools-0.2.15-r1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside-tools/pyside-tools-0.2.15-r1.ebuild,v 1.1 2015/03/23 10:11:42 yngwin Exp $
+
+EAPI=5
+CMAKE_IN_SOURCE_BUILD="1"
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+VIRTUALX_COMMAND="cmake-utils_src_test"
+
+inherit eutils cmake-utils python-r1 vcs-snapshot virtualx
+
+DESCRIPTION="PySide development tools (lupdate, rcc, uic)"
+HOMEPAGE="http://qt-project.org/wiki/PySide"
+SRC_URI="https://github.com/PySide/Tools/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=dev-python/pyside-1.2.0[X,${PYTHON_USEDEP}]
+	>=dev-python/shiboken-1.2.0[${PYTHON_USEDEP}]
+	>=dev-qt/qtcore-4.7.0:4
+	>=dev-qt/qtgui-4.7.0:4
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	test? ( virtual/pkgconfig )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/0.2.13-fix-pysideuic-test-and-install.patch
+
+	python_copy_sources
+
+	preparation() {
+		pushd "${BUILD_DIR}" >/dev/null || die
+		if python_is_python3; then
+			rm -fr pysideuic/port_v2
+		else
+			rm -fr pysideuic/port_v3
+		fi
+
+		sed -i -e "/pkg-config/ s:shiboken:&-${EPYTHON}:" \
+			tests/rcc/run_test.sh || die
+		popd >/dev/null || die
+	}
+	python_foreach_impl preparation
+}
+
+src_configure() {
+	configuration() {
+		local mycmakeargs=(
+			-DPYTHON_BASENAME="-${EPYTHON}"
+			-DPYTHON_SUFFIX="-${EPYTHON}"
+			$(cmake-utils_use_build test TESTS)
+		)
+		CMAKE_USE_DIR="${BUILD_DIR}" cmake-utils_src_configure
+	}
+	python_foreach_impl configuration
+}
+
+src_compile() {
+	compilation() {
+		CMAKE_USE_DIR="${BUILD_DIR}" cmake-utils_src_make
+	}
+	python_foreach_impl compilation
+}
+
+src_test() {
+	testing() {
+		CMAKE_USE_DIR="${BUILD_DIR}" virtualmake
+	}
+	python_foreach_impl testing
+}
+
+src_install() {
+	installation() {
+		CMAKE_USE_DIR="${BUILD_DIR}" cmake-utils_src_install DESTDIR="${D}"
+	}
+	python_foreach_impl installation
+
+	dodoc AUTHORS
+}