bump; re-addition of inital doc build and a viable test phase subsequent to pull requests submitted by wking and accepted by upstream

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 75 insertions, 1 deletions

diff --git a/dev-python/flask-cors/ChangeLog b/dev-python/flask-cors/ChangeLog
index 6423058eb632..5829e3f6ae59 100644
--- a/dev-python/flask-cors/ChangeLog
+++ b/dev-python/flask-cors/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/flask-cors
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-cors/ChangeLog,v 1.2 2014/09/14 18:26:54 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-cors/ChangeLog,v 1.3 2014/09/23 14:10:01 idella4 Exp $
+
+*flask-cors-1.9.0 (23 Sep 2014)
+
+  23 Sep 2014; Ian Delaney <idella4@gentoo.org> +flask-cors-1.9.0.ebuild:
+  bump; re-addition of inital doc build and a viable test phase subsequent to
+  pull requests submitted by wking and accepted by upstream
 
   14 Sep 2014; Mike Gilbert <floppym@gentoo.org> flask-cors-1.8.0.ebuild:
   Drop docs build until a more reasonable solution can be found. Acknowledged by
diff --git a/dev-python/flask-cors/flask-cors-1.9.0.ebuild b/dev-python/flask-cors/flask-cors-1.9.0.ebuild
new file mode 100644
index 000000000000..a497655cbcf9
--- /dev/null
+++ b/dev-python/flask-cors/flask-cors-1.9.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-cors/flask-cors-1.9.0.ebuild,v 1.1 2014/09/23 14:10:01 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="Flask-Cors"
+MY_P="${MY_PN}-${PV}"
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://github.com/wcdolphin/${PN}.git"
+	SRC_URI=""
+else
+	SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
+fi
+
+DESCRIPTION="A Flask extension for Cross Origin Resource Sharing (CORS)"
+HOMEPAGE="https://github.com/wcdolphin/flask-cors https://pypi.python.org/pypi/Flask-Cors"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		${RDEPEND}
+		>=dev-python/python-docs-2.7.6-r1:2.7
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	if use doc; then
+		local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
+		local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
+		local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
+		local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
+		sed -i "s|'http://docs.python.org/': None|'${PYTHON_DOC}': '${PYTHON_DOC_INVENTORY}'|" docs/conf.py || die
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}