Version bump.

(Portage version: 2.2_rc33/cvs/Linux x86_64)

2 files changed, 53 insertions, 1 deletions

diff --git a/dev-libs/zziplib/ChangeLog b/dev-libs/zziplib/ChangeLog
index 6c745fbfe97d..ec5d1ee6fd2f 100644
--- a/dev-libs/zziplib/ChangeLog
+++ b/dev-libs/zziplib/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/zziplib
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/zziplib/ChangeLog,v 1.67 2009/06/24 21:09:36 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/zziplib/ChangeLog,v 1.68 2009/06/28 16:35:26 vapier Exp $
+
+*zziplib-0.13.56 (28 Jun 2009)
+
+  28 Jun 2009; Mike Frysinger <vapier@gentoo.org> +zziplib-0.13.56.ebuild:
+  Version bump.
 
   24 Jun 2009; Michael Sterrett <mr_bones_@gentoo.org>
   zziplib-0.13.55.ebuild:
diff --git a/dev-libs/zziplib/zziplib-0.13.56.ebuild b/dev-libs/zziplib/zziplib-0.13.56.ebuild
new file mode 100644
index 000000000000..6d5c1261d9fe
--- /dev/null
+++ b/dev-libs/zziplib/zziplib-0.13.56.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/zziplib/zziplib-0.13.56.ebuild,v 1.1 2009/06/28 16:35:26 vapier Exp $
+
+EAPI="2"
+inherit libtool eutils flag-o-matic
+
+DESCRIPTION="Lightweight library used to easily extract data from files archived in a single zip file"
+HOMEPAGE="http://zziplib.sourceforge.net/"
+SRC_URI="mirror://sourceforge/zziplib/${P}.tar.bz2"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="sdl test"
+
+RDEPEND=">=dev-lang/python-2.4
+	sys-libs/zlib
+	sdl? ( >=media-libs/libsdl-1.2.6 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	test? ( app-arch/zip )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.13.49-SDL-test.patch
+	# zziplib tries to install backwards compat symlinks we dont want
+	sed -i -e '/^zzip-postinstall:/s|$|\ndisable-this:|' Makefile.in || die
+	sed -i -e '/^install-exec-local:/s|$|\ndisable-this:|' zzip/Makefile.in || die
+	elibtoolize
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing # bug reported upstream
+	econf $(use_enable sdl)
+}
+
+src_test() {
+	# need this because `make test` will always return true
+	# tests fail with -j > 1 (bug #241186)
+	emake -j1 check || die "make check failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-man3 || die "make install failed"
+	dodoc ChangeLog README TODO
+	dohtml docs/*
+}