Version bump for Gnome 3.10, drop old

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

4 files changed, 89 insertions, 88 deletions

diff --git a/dev-libs/folks/ChangeLog b/dev-libs/folks/ChangeLog
index c3dd61b1ba21..71cc1261c13f 100644
--- a/dev-libs/folks/ChangeLog
+++ b/dev-libs/folks/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/folks
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/ChangeLog,v 1.36 2013/12/08 17:55:49 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/ChangeLog,v 1.37 2013/12/24 15:47:09 pacho Exp $
+
+*folks-0.9.6 (24 Dec 2013)
+
+  24 Dec 2013; Pacho Ramos <pacho@gentoo.org> +folks-0.9.6.ebuild,
+  -folks-0.8.0.ebuild, metadata.xml:
+  Version bump for Gnome 3.10, drop old
 
   08 Dec 2013; Pacho Ramos <pacho@gentoo.org> folks-0.9.3.ebuild:
   x86 stable, bug #478252
diff --git a/dev-libs/folks/folks-0.8.0.ebuild b/dev-libs/folks/folks-0.8.0.ebuild
deleted file mode 100644
index 81692c6fc900..000000000000
--- a/dev-libs/folks/folks-0.8.0.ebuild
+++ /dev/null
@@ -1,86 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/folks-0.8.0.ebuild,v 1.5 2013/02/02 22:24:49 ago Exp $
-
-EAPI="5"
-GCONF_DEBUG="yes"
-GNOME2_LA_PUNT="yes"
-VALA_MIN_API_VERSION="0.18"
-VALA_USE_DEPEND="vapigen"
-
-inherit eutils gnome2 vala virtualx
-
-DESCRIPTION="libfolks is a library that aggregates people from multiple sources"
-HOMEPAGE="http://telepathy.freedesktop.org/wiki/Folks"
-
-LICENSE="LGPL-2.1+"
-SLOT="0/25" # subslot = libfolks soname version
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
-# TODO: --enable-profiling
-IUSE="eds socialweb +telepathy test tracker utils vala"
-
-COMMON_DEPEND="
-	>=dev-libs/glib-2.32:2
-	dev-libs/dbus-glib
-	<dev-libs/libgee-0.7:0[introspection]
-	dev-libs/libxml2
-	sys-libs/ncurses:=
-	sys-libs/readline:=
-
-	eds? ( >=gnome-extra/evolution-data-server-3.5.4:= )
-	socialweb? ( >=net-libs/libsocialweb-0.25.20 )
-	telepathy? (
-		>=dev-libs/libzeitgeist-0.3.14:=
-		>=net-libs/telepathy-glib-0.19 )
-	tracker? ( >=app-misc/tracker-0.14:= )
-"
-# telepathy-mission-control needed at runtime; it is used by the telepathy
-# backend via telepathy-glib's AccountManager binding.
-RDEPEND="${COMMON_DEPEND}
-	net-im/telepathy-mission-control
-"
-# folks socialweb backend requires that libsocialweb be built with USE=vala,
-# even when building folks with --disable-vala.
-DEPEND="${COMMON_DEPEND}
-	>=dev-libs/gobject-introspection-1.30
-	>=dev-util/intltool-0.50.0
-	sys-devel/gettext
-	virtual/pkgconfig
-
-	socialweb? ( >=net-libs/libsocialweb-0.25.15[vala] )
-	test? ( sys-apps/dbus )
-	vala? (
-		$(vala_depend)
-		>=net-libs/telepathy-glib-0.13.1[vala]
-		eds? ( >=gnome-extra/evolution-data-server-3.5.4:=[vala] ) )
-"
-# the inspect tool requires --enable-vala
-REQUIRED_USE="utils? ( vala )"
-
-src_prepare() {
-	local vala_version=$(vala_best_api_version)
-	# Rebuilding docs needs valadoc, which has no release
-	G2CONF="${G2CONF}
-		$(use_enable eds eds-backend)
-		$(use_enable socialweb libsocialweb-backend)
-		$(use_enable telepathy telepathy-backend)
-		$(use_enable tracker tracker-backend)
-		$(use_enable utils inspect-tool)
-		$(use_enable vala)
-		$(use_enable test tests)
-		--enable-import-tool
-		--disable-docs
-		--disable-fatal-warnings
-		VALAC=$(type -p valac-${vala_version})
-		VAPIGEN=$(type -p vapigen-${vala_version})"
-
-	# We don't need vala_src_prepare
-	gnome2_src_prepare
-}
-
-src_test() {
-	# FIXME: eds tests often fails for no good reason
-	#sed -e 's/check: .*/check: /' \
-	#	-i tests/eds/Makefile || die "sed failed"
-	dbus-launch Xemake check
-}
diff --git a/dev-libs/folks/folks-0.9.6.ebuild b/dev-libs/folks/folks-0.9.6.ebuild
new file mode 100644
index 000000000000..f4845cfda613
--- /dev/null
+++ b/dev-libs/folks/folks-0.9.6.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/folks/folks-0.9.6.ebuild,v 1.1 2013/12/24 15:47:09 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+VALA_MIN_API_VERSION="0.22"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala virtualx
+
+DESCRIPTION="Library for aggregating people from multiple sources"
+HOMEPAGE="https://live.gnome.org/Folks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/25" # subslot = libfolks soname version
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
+# TODO: --enable-profiling
+# Vala isn't really optional, https://bugzilla.gnome.org/show_bug.cgi?id=701099
+IUSE="bluetooth eds socialweb +telepathy test tracker utils zeitgeist"
+REQUIRED_USE="bluetooth? ( eds )"
+
+COMMON_DEPEND="
+	$(vala_depend)
+	>=dev-libs/glib-2.38.2:2
+	dev-libs/dbus-glib
+	>=dev-libs/libgee-0.10:0.8[introspection]
+	dev-libs/libxml2
+	sys-libs/ncurses:=
+	sys-libs/readline:=
+
+	bluetooth? ( >=net-wireless/bluez-5 )
+	eds? ( >=gnome-extra/evolution-data-server-3.9.1:=[vala] )
+	socialweb? ( >=net-libs/libsocialweb-0.25.20 )
+	telepathy? ( >=net-libs/telepathy-glib-0.19[vala] )
+	tracker? ( >=app-misc/tracker-0.16:= )
+	zeitgeist? ( >=gnome-extra/zeitgeist-0.9.14 )
+"
+# telepathy-mission-control needed at runtime; it is used by the telepathy
+# backend via telepathy-glib's AccountManager binding.
+RDEPEND="${COMMON_DEPEND}
+	net-im/telepathy-mission-control
+"
+# folks socialweb backend requires that libsocialweb be built with USE=vala,
+# even when building folks with --disable-vala.
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/gobject-introspection-1.30
+	>=dev-util/intltool-0.50.0
+	sys-devel/gettext
+	virtual/pkgconfig
+
+	socialweb? ( >=net-libs/libsocialweb-0.25.15[vala] )
+	test? ( sys-apps/dbus )
+	!<dev-lang/vala-0.22.1:0.22
+"
+
+src_prepare() {
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# Rebuilding docs needs valadoc, which has no release
+	gnome2_src_configure \
+		$(use_enable bluetooth bluez-backend) \
+		$(use_enable eds eds-backend) \
+		$(use_enable eds ofono-backend) \
+		$(use_enable socialweb libsocialweb-backend) \
+		$(use_enable telepathy telepathy-backend) \
+		$(use_enable tracker tracker-backend) \
+		$(use_enable utils inspect-tool) \
+		$(use_enable test tests) \
+		$(use_enable zeitgeist) \
+		--enable-vala \
+		--enable-import-tool \
+		--disable-docs \
+		--disable-fatal-warnings
+}
+
+src_test() {
+	dbus-launch Xemake check
+}
diff --git a/dev-libs/folks/metadata.xml b/dev-libs/folks/metadata.xml
index 1742780aad9f..5a4e0a796e42 100644
--- a/dev-libs/folks/metadata.xml
+++ b/dev-libs/folks/metadata.xml
@@ -7,7 +7,6 @@
 	<flag name="tracker">Load contacts from <pkg>app-misc/tracker</pkg> index</flag>
 	<flag name="telepathy">Load contacts from the Telepathy framework</flag>
 	<flag name="utils">Build the folks-inspect utility</flag>
-	<flag name="vala">Regenerate pre-generated C code from Vala source</flag>
 	<flag name="zeitgeist">Add support for Zeitgeist event tracking system</flag>
 </use>
 </pkgmetadata>