summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJustin Lecher <jlec@gentoo.org>2012-06-07 16:47:30 +0000
committerJustin Lecher <jlec@gentoo.org>2012-06-07 16:47:30 +0000
commitea9972e8ecfdfcc000fd3920ac807161f467815c (patch)
treea45e1a766aacecc188896a4f414849c4c8a164c7 /dev-lang
parentFix build with GCC 4.7 wrt bug #413951. Thanks to Olivier Huber <oli.huber@gm... (diff)
downloadgentoo-2-ea9972e8ecfdfcc000fd3920ac807161f467815c.tar.gz
gentoo-2-ea9972e8ecfdfcc000fd3920ac807161f467815c.tar.bz2
gentoo-2-ea9972e8ecfdfcc000fd3920ac807161f467815c.zip
dev-lang/tk: Drop standard lib locataion from tkConfig.sh equal to tcl, #420129
(Portage version: 2.2.0_alpha110/cvs/Linux x86_64)
Diffstat (limited to 'dev-lang')
-rw-r--r--dev-lang/tk/ChangeLog7
-rw-r--r--dev-lang/tk/tk-8.5.11-r1.ebuild118
2 files changed, 124 insertions, 1 deletions
diff --git a/dev-lang/tk/ChangeLog b/dev-lang/tk/ChangeLog
index 81814eddfa43..94f09a6c2bc5 100644
--- a/dev-lang/tk/ChangeLog
+++ b/dev-lang/tk/ChangeLog
@@ -1,6 +1,11 @@
# ChangeLog for dev-lang/tk
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/ChangeLog,v 1.170 2012/04/26 19:49:06 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/ChangeLog,v 1.171 2012/06/07 16:47:30 jlec Exp $
+
+*tk-8.5.11-r1 (07 Jun 2012)
+
+ 07 Jun 2012; Justin Lecher <jlec@gentoo.org> +tk-8.5.11-r1.ebuild:
+ Drop standard lib locataion from tkConfig.sh equal to tcl, #420129
26 Apr 2012; Alexis Ballier <aballier@gentoo.org> tk-8.5.11.ebuild:
keyword ~amd64-fbsd
diff --git a/dev-lang/tk/tk-8.5.11-r1.ebuild b/dev-lang/tk/tk-8.5.11-r1.ebuild
new file mode 100644
index 000000000000..eda09d30913e
--- /dev/null
+++ b/dev-lang/tk/tk-8.5.11-r1.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.5.11-r1.ebuild,v 1.1 2012/06/07 16:47:30 jlec Exp $
+
+EAPI=4
+
+inherit autotools eutils multilib toolchain-funcs prefix
+
+MY_P="${PN}${PV/_beta/b}"
+
+DESCRIPTION="Tk Widget Set"
+HOMEPAGE="http://www.tcl.tk/"
+SRC_URI="mirror://sourceforge/tcl/${MY_P}-src.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug threads truetype aqua xscreensaver"
+
+RDEPEND="
+ !aqua? (
+ x11-libs/libX11
+ x11-libs/libXt
+ truetype? ( x11-libs/libXft )
+ xscreensaver? ( x11-libs/libXScrnSaver ) )
+ ~dev-lang/tcl-${PV}"
+DEPEND="${RDEPEND}
+ !aqua? ( x11-proto/xproto )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+ epatch "${FILESDIR}"/${P}-fedora-xft.patch
+ epatch "${FILESDIR}"/${PN}-8.4.11-multilib.patch
+
+ epatch "${FILESDIR}"/${PN}-8.4.15-aqua.patch
+ eprefixify unix/Makefile.in
+
+ # Bug 125971
+ epatch "${FILESDIR}"/${PN}-8.5_alpha6-tclm4-soname.patch
+
+ # Bug 354067 : the same applies to tk, since the patch is about tcl.m4, just
+ # copy the tcl patch
+ epatch "${FILESDIR}"/tcl-8.5.9-gentoo-fbsd.patch
+
+ sed -i 's/FT_New_Face/XftFontOpen/g' unix/configure.in || die
+
+ cd "${S}"/unix
+ eautoreconf
+}
+
+src_configure() {
+ tc-export CC
+ cd "${S}"/unix
+
+ local mylibdir=$(get_libdir)
+
+ econf \
+ --with-tcl="${EPREFIX}/usr/${mylibdir}" \
+ $(use_enable threads) \
+ $(use_enable aqua) \
+ $(use_enable truetype xft) \
+ $(use_enable xscreensaver xss) \
+ $(use_enable debug symbols)
+}
+
+src_compile() {
+ cd "${S}"/unix && emake
+}
+
+src_install() {
+ #short version number
+ local v1
+ v1=${PV%.*}
+
+ cd "${S}"/unix
+ S= emake DESTDIR="${D}" install
+
+ # normalize $S path, bug #280766 (pkgcore)
+ local nS="$(cd "${S}"; pwd)"
+
+ # fix the tkConfig.sh to eliminate refs to the build directory
+ local mylibdir=$(get_libdir); mylibdir=${mylibdir//\/}
+ sed -i \
+ -e "s,^TK_BUILD_LIB_SPEC='-L.*/unix ,TK_BUILD_LIB_SPEC='," \
+ -e "s,^TK_SRC_DIR='.*',TK_SRC_DIR='${EPREFIX}/usr/${mylibdir}/tk${v1}/include'," \
+ -e "s,^TK_BUILD_STUB_LIB_SPEC='-L.*/unix ,TK_BUILD_STUB_LIB_SPEC='," \
+ -e "s,^TK_BUILD_STUB_LIB_PATH='.*/unix,TK_BUILD_STUB_LIB_PATH='${EPREFIX}/usr/${mylibdir}," \
+ -e "s,^TK_LIB_FILE='libtk${v1}..TK_DBGX..so',TK_LIB_FILE=\"libtk${v1}\$\{TK_DBGX\}.so\"," \
+ -e "s,^TK_STUB_LIB_SPEC='-L${EPREFIX}/usr/${mylibdir} ,TK_STUB_LIB_SPEC='," \
+ -e "s,^TK_LIB_SPEC='-L${EPREFIX}/usr/${mylibdir} ,TK_LIB_SPEC='," \
+ "${ED}"/usr/${mylibdir}/tkConfig.sh || die
+ if [[ ${CHOST} != *-darwin* && ${CHOST} != *-mint* ]] ; then
+ sed -i \
+ -e "s,^\(TK_CC_SEARCH_FLAGS='.*\)',\1:${EPREFIX}/usr/${mylibdir}'," \
+ -e "s,^\(TK_LD_SEARCH_FLAGS='.*\)',\1:${EPREFIX}/usr/${mylibdir}'," \
+ "${ED}"/usr/${mylibdir}/tkConfig.sh || die
+ fi
+
+ # install private headers
+ insinto /usr/${mylibdir}/tk${v1}/include/unix
+ doins "${S}"/unix/*.h
+ insinto /usr/${mylibdir}/tk${v1}/include/generic
+ doins "${S}"/generic/*.h
+ rm -f "${ED}"/usr/${mylibdir}/tk${v1}/include/generic/tk.h
+ rm -f "${ED}"/usr/${mylibdir}/tk${v1}/include/generic/tkDecls.h
+ rm -f "${ED}"/usr/${mylibdir}/tk${v1}/include/generic/tkPlatDecls.h
+
+ # install symlink for libraries
+ #dosym libtk${v1}.a /usr/${mylibdir}/libtk.a
+ dosym libtk${v1}$(get_libname) /usr/${mylibdir}/libtk$(get_libname)
+ dosym libtkstub${v1}.a /usr/${mylibdir}/libtkstub.a
+
+ dosym wish${v1} /usr/bin/wish
+
+ cd "${S}"
+ dodoc ChangeLog* README changes
+}