Bump rc5 up to 2.0.0 final.

(Portage version: 2.2.0_alpha144_p1/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 78 insertions, 1 deletions

diff --git a/app-portage/layman/ChangeLog b/app-portage/layman/ChangeLog
index dbbe74ac6a15..fbb1f3438e4b 100644
--- a/app-portage/layman/ChangeLog
+++ b/app-portage/layman/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-portage/layman
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.165 2012/11/19 02:45:55 dolsen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.166 2012/12/16 19:15:47 dolsen Exp $
+
+*layman-2.0.0 (16 Dec 2012)
+
+  16 Dec 2012; Brian Dolbec <dolsen@gentoo.org> +layman-2.0.0.ebuild:
+  Bumping rc5 up to 2.0.0 final.
 
   19 Nov 2012; Brian Dolbec <dolsen@gentoo.org> layman-9999.ebuild:
   fix the pyGPG dep to the correct category.
diff --git a/app-portage/layman/layman-2.0.0.ebuild b/app-portage/layman/layman-2.0.0.ebuild
new file mode 100644
index 000000000000..b0b5ddd903da
--- /dev/null
+++ b/app-portage/layman/layman-2.0.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/layman-2.0.0.ebuild,v 1.1 2012/12/16 19:15:47 dolsen Exp $
+
+EAPI="4"
+SUPPORT_PYTHON_ABIS="1"
+PYTHON_DEPEND="2:2.6"
+RESTRICT_PYTHON_ABIS="2.4 3.*"
+PYTHON_USE_WITH="xml(+)"
+
+inherit eutils distutils prefix
+
+DESCRIPTION="Tool to manage Gentoo overlays"
+HOMEPAGE="http://layman.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bazaar cvs darcs +git mercurial subversion test"
+
+COMMON_DEPS="dev-lang/python"
+DEPEND="${COMMON_DEPS}
+	test? ( dev-vcs/subversion )"
+RDEPEND="${COMMON_DEPS}
+	bazaar? ( dev-vcs/bzr )
+	cvs? ( dev-vcs/cvs )
+	darcs? ( dev-vcs/darcs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	subversion? (
+		|| (
+			>=dev-vcs/subversion-1.5.4[webdav-neon]
+			>=dev-vcs/subversion-1.5.4[webdav-serf]
+		)
+	)"
+
+src_prepare() {
+	eprefixify etc/layman.cfg layman/config.py
+}
+
+src_test() {
+	testing() {
+		for suite in layman/tests/{dtest,external}.py ; do
+			PYTHONPATH="." "$(PYTHON)" ${suite} \
+					|| die "test suite '${suite}' failed"
+		done
+	}
+	python_execute_function testing
+}
+
+src_install() {
+	distutils_src_install
+
+	insinto /etc/layman
+	doins etc/layman.cfg || die
+
+	doman doc/layman.8
+	dohtml doc/layman.8.html
+
+	keepdir /var/lib/layman
+	keepdir /etc/layman/overlays
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+
+	# now run layman's update utility
+	einfo "Running layman-updater..."
+	"${EROOT}"/usr/bin/layman-updater
+	einfo
+}