Version bump.

(Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

2 files changed, 103 insertions, 1 deletions

diff --git a/app-pda/gtkpod/ChangeLog b/app-pda/gtkpod/ChangeLog
index e4dbf98f1f4f..23075bb095d4 100644
--- a/app-pda/gtkpod/ChangeLog
+++ b/app-pda/gtkpod/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-pda/gtkpod
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-pda/gtkpod/ChangeLog,v 1.107 2012/06/19 05:50:42 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-pda/gtkpod/ChangeLog,v 1.108 2012/06/20 08:16:54 ssuominen Exp $
+
+*gtkpod-2.1.2 (20 Jun 2012)
+
+  20 Jun 2012; Samuli Suominen <ssuominen@gentoo.org> +gtkpod-2.1.2.ebuild:
+  Version bump.
 
   19 Jun 2012; Samuli Suominen <ssuominen@gentoo.org>
   gtkpod-2.1.2_beta2.ebuild:
diff --git a/app-pda/gtkpod/gtkpod-2.1.2.ebuild b/app-pda/gtkpod/gtkpod-2.1.2.ebuild
new file mode 100644
index 000000000000..3d79720e6c0c
--- /dev/null
+++ b/app-pda/gtkpod/gtkpod-2.1.2.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-pda/gtkpod/gtkpod-2.1.2.ebuild,v 1.1 2012/06/20 08:16:54 ssuominen Exp $
+
+EAPI=4
+inherit eutils gnome2-utils
+
+DESCRIPTION="A graphical user interface to the Apple productline"
+HOMEPAGE="http://gtkpod.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2 FDL-1.2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="aac clutter curl cdr flac gstreamer mp3 vorbis webkit"
+
+COMMON_DEPEND="dev-libs/gdl:3
+	>=dev-libs/glib-2.28.5
+	>=dev-libs/libxml2-2.7.7
+	>=dev-util/anjuta-2.91
+	>=media-libs/libgpod-0.7.0
+	>=media-libs/libid3tag-0.15
+	>=x11-libs/gtk+-3.0.8:3
+	aac? ( media-libs/faad2 )
+	clutter? ( media-libs/clutter-gtk:1.0 )
+	curl? ( >=net-misc/curl-7.10 )
+	cdr? (
+		>=app-cdr/brasero-3
+		media-libs/musicbrainz:3
+		)
+	flac? ( media-libs/flac )
+	gstreamer? ( >=media-libs/gst-plugins-base-0.10.25:0.10 )
+	mp3? ( media-sound/lame )
+	vorbis? (
+		media-libs/libvorbis
+		media-sound/vorbis-tools
+		)
+	webkit? ( >=net-libs/webkit-gtk-1.3:3 )"
+RDEPEND="${COMMON_DEPEND}
+	gstreamer? ( media-plugins/gst-plugins-meta:0.10 )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/flex
+	sys-devel/gettext
+	virtual/os-headers
+	virtual/pkgconfig"
+
+src_prepare() {
+	# Make sure SLOT="4" is not used. Everyone should move from "3" to "5" directly.
+	sed -i -e '/PKG_CONFIG/s:libmusicbrainz4:&sLoT4iSdEpReCaTeD:' configure || die
+
+	# /path/to/install: '/path/to/app-pda/gtkpod-2.1.2_beta2/image/usr/share/gtkpod/data/rhythmbox.gep’: File exists
+	sed -i -e '/^dist_profiles_DATA/s:=.*:=:' plugins/sjcd/data/Makefile.in || die
+}
+
+src_configure() {
+	export GST_INSPECT=true #420279
+
+	econf \
+		--disable-static \
+		$(use_enable webkit plugin-coverweb) \
+		$(use_enable clutter plugin-clarity) \
+		$(use_enable gstreamer plugin-media-player) \
+		$(use_enable cdr plugin-sjcd) \
+		$(use_with curl) \
+		$(use_with vorbis ogg) \
+		$(use_with flac) \
+		$(use_with aac mp4)
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		docdir=/usr/share/doc/${PF}/html \
+		figuresdir=/usr/share/doc/${PF}/html/figures \
+		install
+
+	prune_libtool_files --all
+
+	dodoc AUTHORS ChangeLog NEWS README TODO TROUBLESHOOTING
+	rm -f "${ED}"/usr/share/gtkpod/data/{AUTHORS,COPYING}
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}