app-office/texstudio: Version BUmp, #505140

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

2 files changed, 90 insertions, 2 deletions

diff --git a/app-office/texstudio/ChangeLog b/app-office/texstudio/ChangeLog
index bc819fec8be2..3d814e2bae0c 100644
--- a/app-office/texstudio/ChangeLog
+++ b/app-office/texstudio/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-office/texstudio
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/texstudio/ChangeLog,v 1.24 2013/11/06 12:39:25 jlec Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/texstudio/ChangeLog,v 1.25 2014/03/20 15:37:43 jlec Exp $
+
+*texstudio-2.7.0 (20 Mar 2014)
+
+  20 Mar 2014; Justin Lecher <jlec@gentoo.org> +texstudio-2.7.0.ebuild:
+  Version BUmp, #505140
 
 *texstudio-2.6.6 (06 Nov 2013)
 
diff --git a/app-office/texstudio/texstudio-2.7.0.ebuild b/app-office/texstudio/texstudio-2.7.0.ebuild
new file mode 100644
index 000000000000..ca8895b899a8
--- /dev/null
+++ b/app-office/texstudio/texstudio-2.7.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/texstudio/texstudio-2.7.0.ebuild,v 1.1 2014/03/20 15:37:43 jlec Exp $
+
+EAPI=5
+
+inherit base fdo-mime prefix qt4-r2
+
+DESCRIPTION="Free cross-platform LaTeX editor (fork from texmakerX)"
+HOMEPAGE="http://texstudio.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}/TeXstudio%20${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="video"
+
+COMMON_DEPEND="
+	app-text/hunspell
+	app-text/poppler:=[qt4]
+	dev-libs/quazip
+	x11-libs/libX11
+	x11-libs/libXext
+	|| ( ( >=dev-qt/qtgui-4.8.5:4 dev-qt/designer:4 ) <dev-qt/qtgui-4.8.5:4 )
+	>=dev-qt/qtcore-4.6.1:4
+	>=dev-qt/qtscript-4.6.1:4
+	dev-qt/qtsingleapplication
+	>=dev-qt/qtsvg-4.6.1:4
+	>=dev-qt/qttest-4.6.1:4
+	video? ( media-libs/phonon )"
+RDEPEND="${COMMON_DEPEND}
+	virtual/latex-base
+	app-text/psutils
+	app-text/ghostscript-gpl
+	media-libs/netpbm"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/-/}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.6.4-hunspell-quazip.patch
+	"${FILESDIR}"/${PN}-2.6.0-desktop.patch
+# Get it from fedora
+	"${FILESDIR}"/${PN}-2.5-viewers-use-xdg-open.patch
+	)
+
+src_prepare() {
+	find hunspell quazip utilities/poppler-data qtsingleapplication -delete || die
+
+	if use video; then
+		sed "/^PHONON/s:$:true:g" -i ${PN}.pro || die
+	fi
+
+	sed \
+		-e '/hunspell.pri/d' \
+		-e '/quazip.pri/d' \
+		-e '/qtsingleapplication.pri/d' \
+		-e '/QUAZIP_STATIC/d' \
+		-i ${PN}.pro || die
+
+	cat >> ${PN}.pro <<- EOF
+	exists(texmakerx_my.pri):include(texmakerx_my.pri)
+	EOF
+
+	cp "${FILESDIR}"/texmakerx_my.pri . || die
+	eprefixify texmakerx_my.pri
+
+	qt4-r2_src_prepare
+}
+
+src_install() {
+	local i
+	for i in 16x16 22x22 32x32 48x48 64x64; do
+		insinto /usr/share/icons/hicolor/${i}
+		newins utilities/${PN}${i}.png ${PN}.png
+	done
+	qt4-r2_src_install
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+}