Version bumps.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

3 files changed, 205 insertions, 2 deletions

diff --git a/app-misc/sphinx/ChangeLog b/app-misc/sphinx/ChangeLog
index d38dfb093ccb..c9e3b9dd95fb 100644
--- a/app-misc/sphinx/ChangeLog
+++ b/app-misc/sphinx/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-misc/sphinx
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/sphinx/ChangeLog,v 1.70 2013/12/22 16:55:06 graaff Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/sphinx/ChangeLog,v 1.71 2014/01/24 07:41:29 graaff Exp $
+
+*sphinx-2.1.5 (24 Jan 2014)
+*sphinx-2.0.10 (24 Jan 2014)
+
+  24 Jan 2014; Hans de Graaff <graaff@gentoo.org> +sphinx-2.0.10.ebuild,
+  +sphinx-2.1.5.ebuild:
+  Version bumps.
 
 *sphinx-2.1.4 (22 Dec 2013)
 
diff --git a/app-misc/sphinx/sphinx-2.0.10.ebuild b/app-misc/sphinx/sphinx-2.0.10.ebuild
new file mode 100644
index 000000000000..1f6dce2cb5fc
--- /dev/null
+++ b/app-misc/sphinx/sphinx-2.0.10.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/sphinx/sphinx-2.0.10.ebuild,v 1.1 2014/01/24 07:41:29 graaff Exp $
+
+EAPI=5
+inherit eutils autotools toolchain-funcs
+
+#MY_P=${P/_/-}
+MY_P=${P}-release
+
+# This has been added by Gentoo, to explicitly version libstemmer.
+# It is the date that http://snowball.tartarus.org/dist/libstemmer_c.tgz was
+# fetched.
+STEMMER_PV="20091122"
+DESCRIPTION="Full-text search engine with support for MySQL and PostgreSQL"
+HOMEPAGE="http://www.sphinxsearch.com/"
+SRC_URI="http://sphinxsearch.com/files/${MY_P}.tar.gz
+	stemmer? ( mirror://gentoo/libstemmer_c-${STEMMER_PV}.tgz )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~ppc-macos ~x86-macos ~sparc-solaris ~sparc64-solaris"
+IUSE="debug id64 mysql odbc postgres stemmer test"
+
+RDEPEND="mysql? ( virtual/mysql )
+	postgres? ( dev-db/postgresql-base )
+	odbc? ( dev-db/unixODBC )
+	virtual/libiconv"
+DEPEND="${RDEPEND}
+	test? ( dev-lang/php )"
+
+S=${WORKDIR}/${MY_P}
+
+src_unpack() {
+	unpack ${MY_P}.tar.gz
+	if use stemmer; then
+		cd "${S}"
+		unpack libstemmer_c-${STEMMER_PV}.tgz
+	fi
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.0.1_beta-darwin8.patch
+
+	# drop nasty hardcoded search path breaking Prefix
+	# We patch configure directly since otherwise we need to run
+	# eautoreconf twice and that causes problems, bug 425380
+	sed -i -e 's/\/usr\/local\//\/someplace\/nonexisting\//g' configure || die
+
+	# Fix QA compilation warnings.
+	sed -i -e '19i#include <string.h>' api/libsphinxclient/test.c || die
+
+	pushd api/libsphinxclient || die
+	eautoreconf
+	popd || die
+}
+
+src_configure() {
+	# fix libiconv detection
+	use !elibc_glibc && export ac_cv_search_iconv=-liconv
+
+	econf \
+		--sysconfdir="${EPREFIX}/etc/${PN}" \
+		$(use_enable id64) \
+		$(use_with debug) \
+		$(use_with mysql) \
+		$(use_with odbc unixodbc) \
+		$(use_with postgres pgsql) \
+		$(use_with stemmer libstemmer)
+
+	cd api/libsphinxclient || die
+	econf STRIP=:
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" || die "emake failed"
+
+	emake -j 1 -C api/libsphinxclient || die "emake libsphinxclient failed"
+}
+
+src_test() {
+	elog "Tests require access to a live MySQL database and may require configuration."
+	elog "You will find them in /usr/share/${PN}/test and they require dev-lang/php"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "install failed"
+	emake DESTDIR="${D}" -C api/libsphinxclient install || die "install libsphinxclient failed"
+
+	dodoc doc/*
+
+	dodir /var/lib/sphinx
+	dodir /var/log/sphinx
+
+	newinitd "${FILESDIR}"/searchd.rc searchd
+
+	if use test; then
+		insinto /usr/share/${PN}
+		doins -r test
+	fi
+}
diff --git a/app-misc/sphinx/sphinx-2.1.5.ebuild b/app-misc/sphinx/sphinx-2.1.5.ebuild
new file mode 100644
index 000000000000..d27942842515
--- /dev/null
+++ b/app-misc/sphinx/sphinx-2.1.5.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/sphinx/sphinx-2.1.5.ebuild,v 1.1 2014/01/24 07:41:29 graaff Exp $
+
+EAPI=5
+inherit eutils autotools toolchain-funcs
+
+#MY_P=${P/_/-}
+MY_P=${P}-release
+
+# This has been added by Gentoo, to explicitly version libstemmer.
+# It is the date that http://snowball.tartarus.org/dist/libstemmer_c.tgz was
+# fetched.
+#STEMMER_PV="20091122"
+DESCRIPTION="Full-text search engine with support for MySQL and PostgreSQL"
+HOMEPAGE="http://www.sphinxsearch.com/"
+SRC_URI="http://sphinxsearch.com/files/${MY_P}.tar.gz"
+#	stemmer? ( mirror://gentoo/libstemmer_c-${STEMMER_PV}.tgz )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~ppc-macos ~x86-macos ~sparc-solaris ~sparc64-solaris"
+IUSE="debug id64 mysql odbc postgres stemmer syslog test xml"
+
+RDEPEND="mysql? ( virtual/mysql )
+	postgres? ( dev-db/postgresql-base )
+	odbc? ( dev-db/unixODBC )
+	stemmer? ( dev-libs/snowball-stemmer )
+	xml? ( dev-libs/expat )
+	virtual/libiconv"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.0.1_beta-darwin8.patch
+
+	# drop nasty hardcoded search path breaking Prefix
+	# We patch configure directly since otherwise we need to run
+	# eautoreconf twice and that causes problems, bug 425380
+	sed -i -e 's/\/usr\/local\//\/someplace\/nonexisting\//g' configure || die
+
+	# Fix QA compilation warnings.
+	sed -i -e '19i#include <string.h>' api/libsphinxclient/test.c || die
+
+	pushd api/libsphinxclient || die
+	eautoreconf
+	popd || die
+}
+
+src_configure() {
+	# fix libiconv detection
+	use !elibc_glibc && export ac_cv_search_iconv=-liconv
+
+	econf \
+		--sysconfdir="${EPREFIX}/etc/${PN}" \
+		$(use_enable id64) \
+		$(use_with debug) \
+		$(use_with mysql) \
+		$(use_with odbc unixodbc) \
+		$(use_with postgres pgsql) \
+		$(use_with stemmer libstemmer) \
+		$(use_with syslog syslog) \
+		$(use_with xml libexpat )
+
+	cd api/libsphinxclient || die
+	econf STRIP=:
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" || die "emake failed"
+
+	emake -j 1 -C api/libsphinxclient || die "emake libsphinxclient failed"
+}
+
+src_test() {
+	elog "Tests require access to a live MySQL database and may require configuration."
+	elog "You will find them in /usr/share/${PN}/test and they require dev-lang/php"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "install failed"
+	emake DESTDIR="${D}" -C api/libsphinxclient install || die "install libsphinxclient failed"
+
+	dodoc doc/*
+
+	dodir /var/lib/sphinx
+	dodir /var/log/sphinx
+
+	newinitd "${FILESDIR}"/searchd.rc searchd
+
+	if use test; then
+		insinto /usr/share/${PN}
+		doins -r test
+	fi
+}