Version bumped. Added introspection USE flag. Fixed X and gtk USE flags issue, bug #342903.

(Portage version: 2.1.9.22/cvs/Linux x86_64)

6 files changed, 158 insertions, 9 deletions

diff --git a/app-i18n/ibus/ChangeLog b/app-i18n/ibus/ChangeLog
index 24c8ff8285b8..7653d82d3a42 100644
--- a/app-i18n/ibus/ChangeLog
+++ b/app-i18n/ibus/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for app-i18n/ibus
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ChangeLog,v 1.70 2010/10/25 16:13:55 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ChangeLog,v 1.71 2010/11/05 14:11:27 matsuu Exp $
+
+*ibus-1.3.99.20101028 (05 Nov 2010)
+
+  05 Nov 2010; MATSUU Takuto <matsuu@gentoo.org> ibus-1.2.0.20100111.ebuild,
+  ibus-1.3.7.ebuild, ibus-1.3.8.ebuild, +ibus-1.3.99.20101028.ebuild,
+  metadata.xml:
+  Version bumped. Added introspection USE flag. Fixed X and gtk USE flags
+  issue, bug #342903.
 
 *ibus-1.3.8 (25 Oct 2010)
 
diff --git a/app-i18n/ibus/ibus-1.2.0.20100111.ebuild b/app-i18n/ibus/ibus-1.2.0.20100111.ebuild
index 28fb11215e92..96ed449ae357 100644
--- a/app-i18n/ibus/ibus-1.2.0.20100111.ebuild
+++ b/app-i18n/ibus/ibus-1.2.0.20100111.ebuild
@@ -1,9 +1,9 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ibus-1.2.0.20100111.ebuild,v 1.5 2010/08/11 18:15:25 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ibus-1.2.0.20100111.ebuild,v 1.6 2010/11/05 14:11:27 matsuu Exp $
 
 EAPI="1"
-inherit eutils gnome2-utils multilib python
+inherit confutils eutils gnome2-utils multilib python
 
 DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
 HOMEPAGE="http://code.google.com/p/ibus/"
@@ -39,6 +39,8 @@ RDEPEND="${RDEPEND}
 RESTRICT="test"
 
 pkg_setup() {
+	# bug #342903
+	confutils_require_any X gtk
 	# An arch specific config directory is used on multilib systems
 	has_multilib_profile && GTK2_CONFDIR="/etc/gtk-2.0/${CHOST}"
 	GTK2_CONFDIR=${GTK2_CONFDIR:=/etc/gtk-2.0/}
diff --git a/app-i18n/ibus/ibus-1.3.7.ebuild b/app-i18n/ibus/ibus-1.3.7.ebuild
index 977683e99ee2..49ddd21d2fc2 100644
--- a/app-i18n/ibus/ibus-1.3.7.ebuild
+++ b/app-i18n/ibus/ibus-1.3.7.ebuild
@@ -1,10 +1,10 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ibus-1.3.7.ebuild,v 1.3 2010/09/18 17:43:44 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ibus-1.3.7.ebuild,v 1.4 2010/11/05 14:11:27 matsuu Exp $
 
 EAPI="2"
 PYTHON_DEPEND="python? 2:2.5"
-inherit eutils gnome2-utils multilib python
+inherit confutils eutils gnome2-utils multilib python
 
 DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
 HOMEPAGE="http://code.google.com/p/ibus/"
@@ -13,7 +13,7 @@ SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz"
 LICENSE="LGPL-2.1"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
-IUSE="doc +gconf gtk nls +python vala X"
+IUSE="doc +gconf gtk introspection nls +python vala X"
 
 RDEPEND=">=dev-libs/glib-2.18
 	gconf? ( >=gnome-base/gconf-2.12 )
@@ -27,6 +27,7 @@ RDEPEND=">=dev-libs/glib-2.18
 		x11-libs/libX11
 		x11-libs/gtk+:2
 	)
+	introspection? ( >=dev-libs/gobject-introspection-0.6.8 )
 	python? (
 		dev-python/notify-python
 		>=dev-python/dbus-python-0.83
@@ -60,6 +61,8 @@ update_gtk_immodules() {
 }
 
 pkg_setup() {
+	# bug #342903
+	confutils_require_any X gtk
 	python_set_active_version 2
 }
 
@@ -74,6 +77,7 @@ src_configure() {
 	econf \
 		$(use_enable doc gtk-doc) \
 		$(use_enable doc gtk-doc-html) \
+		$(use_enable introspection) \
 		$(use_enable gconf) \
 		$(use_enable gtk gtk2) \
 		$(use_enable gtk xim) \
diff --git a/app-i18n/ibus/ibus-1.3.8.ebuild b/app-i18n/ibus/ibus-1.3.8.ebuild
index 4043f8173ef7..506c4e070f17 100644
--- a/app-i18n/ibus/ibus-1.3.8.ebuild
+++ b/app-i18n/ibus/ibus-1.3.8.ebuild
@@ -1,10 +1,10 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ibus-1.3.8.ebuild,v 1.1 2010/10/25 16:13:55 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ibus-1.3.8.ebuild,v 1.2 2010/11/05 14:11:27 matsuu Exp $
 
 EAPI="2"
 PYTHON_DEPEND="python? 2:2.5"
-inherit eutils gnome2-utils multilib python
+inherit confutils eutils gnome2-utils multilib python
 
 DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
 HOMEPAGE="http://code.google.com/p/ibus/"
@@ -13,7 +13,7 @@ SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz"
 LICENSE="LGPL-2.1"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
-IUSE="doc +gconf gtk nls +python vala X"
+IUSE="doc +gconf gtk introspection nls +python vala X"
 
 RDEPEND=">=dev-libs/glib-2.18
 	gconf? ( >=gnome-base/gconf-2.12 )
@@ -27,6 +27,7 @@ RDEPEND=">=dev-libs/glib-2.18
 		x11-libs/libX11
 		x11-libs/gtk+:2
 	)
+	introspection? ( >=dev-libs/gobject-introspection-0.6.8 )
 	python? (
 		dev-python/notify-python
 		>=dev-python/dbus-python-0.83
@@ -60,6 +61,8 @@ update_gtk_immodules() {
 }
 
 pkg_setup() {
+	# bug #342903
+	confutils_require_any X gtk
 	python_set_active_version 2
 }
 
@@ -74,6 +77,7 @@ src_configure() {
 	econf \
 		$(use_enable doc gtk-doc) \
 		$(use_enable doc gtk-doc-html) \
+		$(use_enable introspection) \
 		$(use_enable gconf) \
 		$(use_enable gtk gtk2) \
 		$(use_enable gtk xim) \
diff --git a/app-i18n/ibus/ibus-1.3.99.20101028.ebuild b/app-i18n/ibus/ibus-1.3.99.20101028.ebuild
new file mode 100644
index 000000000000..cd29c59148eb
--- /dev/null
+++ b/app-i18n/ibus/ibus-1.3.99.20101028.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ibus-1.3.99.20101028.ebuild,v 1.1 2010/11/05 14:11:27 matsuu Exp $
+
+EAPI="2"
+PYTHON_DEPEND="python? 2:2.5"
+inherit confutils eutils gnome2-utils multilib python
+
+DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
+HOMEPAGE="http://code.google.com/p/ibus/"
+SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc +gconf gtk introspection nls +python vala X"
+
+RDEPEND=">=dev-libs/glib-2.18
+	gconf? ( >=gnome-base/gconf-2.12 )
+	>=gnome-base/librsvg-2
+	sys-apps/dbus
+	app-text/iso-codes
+	gtk? (
+		x11-libs/gtk+:2
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/gtk+:2
+	)
+	introspection? ( >=dev-libs/gobject-introspection-0.6.8 )
+	python? (
+		dev-python/notify-python
+		>=dev-python/dbus-python-0.83
+	)
+	nls? ( virtual/libintl )
+	vala? ( dev-lang/vala )"
+#	X? ( x11-libs/libX11 )
+#	gtk? ( x11-libs/gtk+:2 x11-libs/gtk+:3 )
+DEPEND="${RDEPEND}
+	>=dev-lang/perl-5.8.1
+	dev-perl/XML-Parser
+	dev-util/pkgconfig
+	doc? ( >=dev-util/gtk-doc-1.9 )
+	nls? ( >=sys-devel/gettext-0.16.1 )"
+RDEPEND="${RDEPEND}
+	python? (
+		dev-python/pygtk
+		dev-python/pyxdg
+	)"
+
+RESTRICT="test"
+
+update_gtk_immodules() {
+	if [ -x /usr/bin/gtk-query-immodules-2.0 ] ; then
+		GTK2_CONFDIR="/etc/gtk-2.0"
+		# An arch specific config directory is used on multilib systems
+		has_multilib_profile && GTK2_CONFDIR="${GTK2_CONFDIR}/${CHOST}"
+		mkdir -p "${ROOT}${GTK2_CONFDIR}"
+		gtk-query-immodules-2.0 > "${ROOT}${GTK2_CONFDIR}/gtk.immodules"
+	fi
+}
+
+pkg_setup() {
+	# bug #342903
+	confutils_require_any X gtk
+	python_set_active_version 2
+}
+
+src_prepare() {
+	mv py-compile py-compile.orig || die
+	ln -s "$(type -P true)" py-compile || die
+	echo "ibus/_config.py" >> po/POTFILES.skip || die
+	sed -i -e "s/python/python2/" setup/ibus-setup.in ui/gtk/ibus-ui-gtk.in || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable doc gtk-doc) \
+		$(use_enable doc gtk-doc-html) \
+		$(use_enable introspection) \
+		$(use_enable gconf) \
+		$(use_enable gtk gtk2) \
+		$(use_enable gtk xim) \
+		$(use_enable nls) \
+		$(use_enable python) \
+		$(use_enable vala) \
+		$(use_enable X xim) || die
+		#$(use_enable gtk gtk3) \
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	# bug 289547
+	keepdir /usr/share/ibus/{engine,icons} || die
+
+	dodoc AUTHORS ChangeLog NEWS README || die
+}
+
+pkg_postinst() {
+
+	elog "To use ibus, you should:"
+	elog "1. Get input engines from sunrise overlay."
+	elog "   Run \"emerge -s ibus-\" in your favorite terminal"
+	elog "   for a list of packages we already have."
+	elog
+	elog "2. Setup ibus:"
+	elog
+	elog "   $ ibus-setup"
+	elog
+	elog "3. Set the following in your user startup scripts"
+	elog "   such as .xinitrc, .xsession or .xprofile:"
+	elog
+	elog "   export XMODIFIERS=\"@im=ibus\""
+	elog "   export GTK_IM_MODULE=\"ibus\""
+	elog "   export QT_IM_MODULE=\"xim\""
+	elog "   ibus-daemon -d -x"
+
+	use gtk && update_gtk_immodules
+
+	use python && python_mod_optimize /usr/share/${PN}
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && update_gtk_immodules
+
+	use python && python_mod_cleanup /usr/share/${PN}
+	gnome2_icon_cache_update
+}
diff --git a/app-i18n/ibus/metadata.xml b/app-i18n/ibus/metadata.xml
index 5ec6adab3420..2f6ee4e46e09 100644
--- a/app-i18n/ibus/metadata.xml
+++ b/app-i18n/ibus/metadata.xml
@@ -10,5 +10,6 @@ developers to develop input method easily.
 <use>
   <flag name='gconf'>Enable support for <pkg>gnome-base/gconf</pkg></flag>
   <flag name='vala'>Enable support for <pkg>dev-lang/vala</pkg></flag>
+  <flag name='introspection'>Use <pkg>dev-libs/gobject-introspection</pkg> for introspection</flag>
 </use>
 </pkgmetadata>