Version bump to 3.0.2 (uses Gtk+ 3); add ncurses USE flag; remove static libraries and .la files. Closes bug #349270.

(Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

1 files changed, 75 insertions, 0 deletions

diff --git a/app-dicts/gwaei/gwaei-3.0.2.ebuild b/app-dicts/gwaei/gwaei-3.0.2.ebuild
new file mode 100644
index 000000000000..d56caccde170
--- /dev/null
+++ b/app-dicts/gwaei/gwaei-3.0.2.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-dicts/gwaei/gwaei-3.0.2.ebuild,v 1.1 2011/08/30 23:07:15 flameeyes Exp $
+
+EAPI="4"
+
+inherit gnome2-utils eutils
+
+DESCRIPTION="Japanese-English Dictionary for GNOME"
+HOMEPAGE="http://gwaei.sourceforge.net/"
+SRC_URI="mirror://sourceforge/gwaei/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gtk nls unique test ncurses"
+
+RDEPEND=">=net-misc/curl-7.21.0
+	>=dev-libs/glib-2.25.0:2
+	gtk? (
+		x11-libs/gtk+:3
+		>=app-text/gnome-doc-utils-0.13.0
+		unique? ( dev-libs/libunique:3 )
+	)
+	ncurses? ( sys-libs/ncurses[unicode] )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	test? ( app-text/docbook-xml-dtd:4.1.2 )
+	gtk? (
+		>=app-text/gnome-doc-utils-0.13.0
+		app-text/scrollkeeper
+	)
+	nls? ( >=sys-devel/gettext-0.17 )
+	dev-util/pkgconfig"
+
+REQUIRED_USE="unique? ( gtk )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-no-ncurses.patch
+}
+
+src_configure() {
+	econf \
+		$(use_with gtk gnome) \
+		$(use_with ncurses) \
+		$(use_with unique libunique) \
+		$(use_enable nls) \
+		--disable-static \
+		--docdir=/usr/share/doc/${PF}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	find "${D}" -name '*.la' -delete
+
+	dodoc AUTHORS README
+}
+
+pkg_preinst() {
+	if use gtk ; then
+		gnome2_schemas_savelist
+	fi
+}
+
+pkg_postinst() {
+	if use gtk ; then
+		gnome2_schemas_update
+	fi
+}
+
+pkg_postrm() {
+	if use gtk ; then
+		gnome2_schemas_update --uninstall
+	fi
+}