Version bump.

(Portage version: 2.2.0_alpha179/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

2 files changed, 74 insertions, 1 deletions

diff --git a/app-arch/xz-utils/ChangeLog b/app-arch/xz-utils/ChangeLog
index e48bf4acbd01..9f65cb3d2318 100644
--- a/app-arch/xz-utils/ChangeLog
+++ b/app-arch/xz-utils/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-arch/xz-utils
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/ChangeLog,v 1.61 2013/02/17 19:48:08 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/ChangeLog,v 1.62 2013/06/30 19:26:28 vapier Exp $
+
+*xz-utils-5.0.5 (30 Jun 2013)
+
+  30 Jun 2013; Mike Frysinger <vapier@gentoo.org> +xz-utils-5.0.5.ebuild:
+  Version bump.
 
   17 Feb 2013; Zac Medico <zmedico@gentoo.org> xz-utils-5.0.4-r1.ebuild:
   Add ~arm-linux keyword.
diff --git a/app-arch/xz-utils/xz-utils-5.0.5.ebuild b/app-arch/xz-utils/xz-utils-5.0.5.ebuild
new file mode 100644
index 000000000000..a90fcff74e50
--- /dev/null
+++ b/app-arch/xz-utils/xz-utils-5.0.5.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/xz-utils-5.0.5.ebuild,v 1.1 2013/06/30 19:26:28 vapier Exp $
+
+# Remember: we cannot leverage autotools in this ebuild in order
+#           to avoid circular deps with autotools
+
+EAPI="4"
+
+inherit eutils multilib toolchain-funcs libtool
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="http://git.tukaani.org/xz.git"
+	inherit git-2 autotools
+	SRC_URI=""
+	EXTRA_DEPEND="sys-devel/gettext dev-vcs/cvs >=sys-devel/libtool-2" #272880 286068
+else
+	MY_P="${PN/-utils}-${PV/_}"
+	SRC_URI="http://tukaani.org/xz/${MY_P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	S=${WORKDIR}/${MY_P}
+	EXTRA_DEPEND=
+fi
+
+DESCRIPTION="utils for managing LZMA compressed files"
+HOMEPAGE="http://tukaani.org/xz/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="nls static-libs +threads"
+
+RDEPEND="!<app-arch/lzma-4.63
+	!app-arch/lzma-utils
+	!<app-arch/p7zip-4.57"
+DEPEND="${RDEPEND}
+	${EXTRA_DEPEND}"
+
+src_prepare() {
+	if [[ ${PV} == "9999" ]] ; then
+		eautopoint
+		eautoreconf
+	else
+		elibtoolize  # to allow building shared libs on Solaris/x64
+	fi
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_enable threads) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	gen_usr_ldscript -a lzma
+	prune_libtool_files --all
+	rm "${ED}"/usr/share/doc/xz/COPYING* || die
+	mv "${ED}"/usr/share/doc/{xz,${PF}} || die
+}
+
+pkg_preinst() {
+	preserve_old_lib /usr/$(get_libdir)/liblzma$(get_libname 0)
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /usr/$(get_libdir)/liblzma$(get_libname 0)
+}