Add new version for Gnome 2.30

(Portage version: 2.1.8.3/cvs/Linux x86_64)

2 files changed, 75 insertions, 1 deletions

diff --git a/app-arch/file-roller/ChangeLog b/app-arch/file-roller/ChangeLog
index f0d0d9556ea6..506dc9ec1e79 100644
--- a/app-arch/file-roller/ChangeLog
+++ b/app-arch/file-roller/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-arch/file-roller
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/ChangeLog,v 1.271 2010/06/04 20:15:35 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/ChangeLog,v 1.272 2010/06/13 19:22:40 pacho Exp $
+
+*file-roller-2.30.1.1 (13 Jun 2010)
+
+  13 Jun 2010; Pacho Ramos <pacho@gentoo.org> +file-roller-2.30.1.1.ebuild:
+  Add new version for Gnome 2.30.
 
   04 Jun 2010; Markus Meier <maekke@gentoo.org> file-roller-2.28.2.ebuild:
   x86 stable, bug #314899
diff --git a/app-arch/file-roller/file-roller-2.30.1.1.ebuild b/app-arch/file-roller/file-roller-2.30.1.1.ebuild
new file mode 100644
index 000000000000..961e151e62d0
--- /dev/null
+++ b/app-arch/file-roller/file-roller-2.30.1.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/file-roller-2.30.1.1.ebuild,v 1.1 2010/06/13 19:22:40 pacho Exp $
+
+EAPI="2"
+GCONF_DEBUG="no"
+
+inherit eutils gnome2
+
+DESCRIPTION="archive manager for GNOME"
+HOMEPAGE="http://fileroller.sourceforge.net/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
+IUSE="nautilus"
+
+RDEPEND=">=dev-libs/glib-2.16.0
+	>=x11-libs/gtk+-2.16
+	gnome-base/gconf
+	nautilus? ( gnome-base/nautilus )"
+DEPEND="${RDEPEND}
+	gnome-base/gnome-common
+	sys-devel/gettext
+	dev-util/intltool
+	dev-util/pkgconfig
+	app-text/gnome-doc-utils"
+
+DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README TODO"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-dependency-tracking
+		--disable-scrollkeeper
+		--disable-run-in-place
+		--disable-static
+		$(use_enable nautilus nautilus-actions)"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Use absolute path to GNU tar since star doesn't have the same
+	# options. On Gentoo, star is /usr/bin/tar, GNU tar is /bin/tar
+	epatch "${FILESDIR}"/${PN}-2.10.3-use_bin_tar.patch
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog "${PN} is a frontend for several archiving utilities. If you want a"
+	elog "particular achive format support, see ${HOMEPAGE}"
+	elog "and install the relevant package."
+	elog
+	elog "for example:"
+	elog "  7-zip   - app-arch/p7zip"
+	elog "  ace     - app-arch/unace"
+	elog "  arj     - app-arch/arj"
+	elog "  lzma    - app-arch/xz-utils"
+	elog "  lzop    - app-arch/lzop"
+	elog "  cpio    - app-arch/cpio"
+	elog "  iso     - app-cdr/cdrtools"
+	elog "  jar,zip - app-arch/zip and app-arch/unzip"
+	elog "  lha     - app-arch/lha"
+	elog "  rar     - app-arch/unrar"
+	elog "  rpm     - app-arch/rpm"
+	elog "  unstuff - app-arch/stuffit"
+	elog "  zoo     - app-arch/zoo"
+}