version bump

(Portage version: 2.1.8.3/cvs/Linux i686)

2 files changed, 117 insertions, 1 deletions

diff --git a/app-admin/syslog-ng/ChangeLog b/app-admin/syslog-ng/ChangeLog
index 1e1d6001e864..8f7eb6af0bdd 100644
--- a/app-admin/syslog-ng/ChangeLog
+++ b/app-admin/syslog-ng/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-admin/syslog-ng
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v 1.243 2010/07/28 03:43:10 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v 1.244 2010/08/04 07:00:16 mr_bones_ Exp $
+
+*syslog-ng-3.1.2 (04 Aug 2010)
+
+  04 Aug 2010; Michael Sterrett <mr_bones_@gentoo.org>
+  +syslog-ng-3.1.2.ebuild:
+  version bump
 
   28 Jul 2010; Michael Sterrett <mr_bones_@gentoo.org>
   -syslog-ng-3.0.7.ebuild:
diff --git a/app-admin/syslog-ng/syslog-ng-3.1.2.ebuild b/app-admin/syslog-ng/syslog-ng-3.1.2.ebuild
new file mode 100644
index 000000000000..6a59f6f15a43
--- /dev/null
+++ b/app-admin/syslog-ng/syslog-ng-3.1.2.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/syslog-ng-3.1.2.ebuild,v 1.1 2010/08/04 07:00:16 mr_bones_ Exp $
+
+EAPI=2
+inherit autotools fixheadtails eutils
+
+MY_PV=${PV/_/}
+DESCRIPTION="syslog replacement with advanced filtering features"
+HOMEPAGE="http://www.balabit.com/products/syslog_ng/"
+SRC_URI="http://www.balabit.com/downloads/files/syslog-ng/sources/${PV}/source/syslog-ng_${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="caps hardened ipv6 pcre selinux spoof-source sql ssl static tcpd"
+RESTRICT="test"
+
+LIBS_DEPEND="
+	spoof-source? ( net-libs/libnet )
+	ssl? ( dev-libs/openssl )
+	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
+	>=dev-libs/eventlog-0.2
+	>=dev-libs/glib-2.10.1:2
+	caps? ( sys-libs/libcap )
+	sql? ( >=dev-db/libdbi-0.8.3 )"
+RDEPEND="
+	!static? (
+		pcre? ( dev-libs/libpcre )
+		${LIBS_DEPEND}
+	)"
+DEPEND="${RDEPEND}
+	${LIBS_DEPEND}
+	dev-util/pkgconfig
+	sys-devel/flex"
+PROVIDE="virtual/logger"
+
+src_prepare() {
+	sed -i \
+		-e 's/mkdir /mkdir $(DESTDIR)/' \
+		scripts/Makefile.am \
+		|| die 'sed failed'
+	ht_fix_file configure.in
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	if use static ; then
+		myconf="${myconf} --enable-static-linking"
+		if use pcre ; then
+			ewarn "USE=pcre is incompatible with static linking"
+			myconf="${myconf} --disable-pcre"
+		fi
+	else
+			myconf="${myconf} --enable-dynamic-linking"
+	fi
+	econf \
+		--disable-dependency-tracking \
+		--sysconfdir=/etc/syslog-ng \
+		--with-pidfile-dir=/var/run \
+		$(use_enable caps linux-caps) \
+		$(use_enable ipv6) \
+		$(use_enable pcre) \
+		$(use_enable spoof-source) \
+		$(use_enable sql) \
+		$(use_enable ssl) \
+		$(use_enable tcpd tcp-wrapper) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	dodoc AUTHORS ChangeLog NEWS README \
+		doc/examples/{syslog-ng.conf.sample,syslog-ng.conf.solaris} \
+		contrib/syslog-ng.conf* \
+		contrib/syslog2ng "${FILESDIR}/syslog-ng.conf."*
+
+	# Install default configuration
+	insinto /etc/syslog-ng
+	if use hardened || use selinux ; then
+		newins "${FILESDIR}/syslog-ng.conf.gentoo.hardened.${PV%%.*}" syslog-ng.conf
+	elif use userland_BSD ; then
+		newins "${FILESDIR}/syslog-ng.conf.gentoo.fbsd.${PV%%.*}" syslog-ng.conf
+	else
+		newins "${FILESDIR}/syslog-ng.conf.gentoo.${PV%%.*}" syslog-ng.conf
+	fi
+
+	insinto /etc/logrotate.d
+	# Install snippet for logrotate, which may or may not be installed
+	if use hardened || use selinux ; then
+		newins "${FILESDIR}/syslog-ng.logrotate.hardened" syslog-ng
+	else
+		newins "${FILESDIR}/syslog-ng.logrotate" syslog-ng
+	fi
+
+	newinitd "${FILESDIR}/syslog-ng.rc6.${PV%%.*}" syslog-ng
+	newconfd "${FILESDIR}/syslog-ng.confd" syslog-ng
+	keepdir /etc/syslog-ng/patterndb.d
+}
+
+pkg_postinst() {
+	echo
+	elog "It is highly recommended that app-admin/logrotate be emerged to"
+	elog "manage the log files.  ${PN} installs a file in /etc/logrotate.d"
+	elog "for logrotate to use."
+	echo
+}