Version bump.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0xE3F69979BB4B8928DA78E3D17CBF44EF)

2 files changed, 85 insertions, 1 deletions

diff --git a/app-admin/salt/ChangeLog b/app-admin/salt/ChangeLog
index e4a61fb8ab0b..62c481ab135b 100644
--- a/app-admin/salt/ChangeLog
+++ b/app-admin/salt/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-admin/salt
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/ChangeLog,v 1.28 2013/12/09 23:19:32 chutzpah Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/ChangeLog,v 1.29 2013/12/12 23:26:17 chutzpah Exp $
+
+*salt-0.17.4 (12 Dec 2013)
+
+  12 Dec 2013; Patrick McLean <chutzpah@gentoo.org> +salt-0.17.4.ebuild:
+  Version bump.
 
   09 Dec 2013; Patrick McLean <chutzpah@gentoo.org> -salt-0.16.0.ebuild,
   -salt-0.16.2.ebuild, -salt-0.16.3.ebuild, salt-0.16.4.ebuild:
diff --git a/app-admin/salt/salt-0.17.4.ebuild b/app-admin/salt/salt-0.17.4.ebuild
new file mode 100644
index 000000000000..36f4854fee5e
--- /dev/null
+++ b/app-admin/salt/salt-0.17.4.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/salt-0.17.4.ebuild,v 1.1 2013/12/12 23:26:17 chutzpah Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=(python{2_6,2_7})
+
+inherit eutils distutils-r1
+
+DESCRIPTION="Salt is a remote execution and configuration manager."
+HOMEPAGE="http://saltstack.org/"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://github.com/${PN}stack/${PN}.git"
+	EGIT_BRANCH="develop"
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~x86 ~amd64"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="ldap libvirt mako mongodb mysql openssl redis test"
+
+RDEPEND=">=dev-python/pyzmq-2.1.9[${PYTHON_USEDEP}]
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/m2crypto[${PYTHON_USEDEP}]
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+		dev-python/pycryptopp[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		sys-apps/pciutils
+		mako? ( dev-python/mako[${PYTHON_USEDEP}] )
+		ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
+		openssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
+		libvirt? ( || (
+			dev-python/libvirt-python[${PYTHON_USEDEP}]
+			app-emulation/libvirt[python,${PYTHON_USEDEP}]
+			)
+		)
+		mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
+		mysql? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
+		redis? ( dev-python/redis-py[${PYTHON_USEDEP}] )"
+DEPEND="test? (
+			dev-python/pip
+			dev-python/virtualenv
+			dev-python/SaltTesting
+			${RDEPEND}
+		)"
+
+PATCHES=("${FILESDIR}/${PN}-0.17.1-tests-nonroot.patch")
+DOCS=(README.rst AUTHORS)
+
+python_prepare() {
+	sed -i '/install_requires=/ d' setup.py || die "sed failed"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	for s in minion master syndic; do
+		newinitd "${FILESDIR}"/${s}-initd-1 salt-${s}
+		newconfd "${FILESDIR}"/${s}-confd-1 salt-${s}
+	done
+
+	insinto /etc/${PN}
+	doins conf/*
+}
+
+python_test() {
+	# testsuite likes lots of files
+	ulimit -n 3072
+	SHELL="/bin/bash" TMPDIR=/tmp ./tests/runtests.py --unit-tests --no-report || die
+}