blob: e174c7c59351ad2c07f83a1069fec19fe8d56e33 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools gnome2-utils xdg-utils virtualx
DESCRIPTION="Compositing window manager forked from Mutter for use with Cinnamon"
HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/muffin"
SRC_URI="https://github.com/linuxmint/muffin/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
IUSE="+introspection test xinerama"
KEYWORDS="amd64 ~arm64 ~riscv ~x86"
RDEPEND="
>=dev-libs/glib-2.37.3:2[dbus]
>=dev-libs/json-glib-1.0
>=gnome-extra/cinnamon-desktop-5.0:0=
gnome-extra/zenity
>=media-libs/libcanberra-0.26[gtk3]
virtual/opengl
>=x11-libs/cairo-1.14:=[X]
x11-libs/gdk-pixbuf:2[introspection?]
>=x11-libs/gtk+-3.9.12:3[X,introspection?]
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
x11-libs/libxcb
>=x11-libs/libXcomposite-0.3
x11-libs/libXcursor
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
>=x11-libs/libXi-1.6.0
>=x11-libs/libxkbcommon-0.4.3[X]
x11-libs/libxkbfile
x11-libs/libXrandr
x11-libs/libXrender
>=x11-libs/pango-1.14.0[X,introspection?]
>=x11-libs/startup-notification-0.7:=
x11-misc/xkeyboard-config
introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
xinerama? ( x11-libs/libXinerama )
"
DEPEND="
${RDEPEND}
x11-base/xorg-proto
test? ( app-text/docbook-xml-dtd:4.5 )
"
# needs gtk-doc, not just -am, for gtk-doc.make
BDEPEND="
dev-util/glib-utils
dev-util/gtk-doc
dev-util/gtk-doc-am
>=dev-util/intltool-0.35
sys-devel/gettext
virtual/pkgconfig
"
src_prepare() {
default
eautoreconf
gnome2_disable_deprecation_warning
}
# Wayland is not supported upstream.
src_configure() {
econf \
--disable-gtk-doc \
--disable-maintainer-mode \
--disable-schemas-compile \
--enable-compile-warnings=minimum \
--disable-static \
--enable-shape \
--enable-sm \
--enable-startup-notification \
--enable-xsync \
--enable-verbose-mode \
--with-libcanberra \
$(use_enable introspection) \
$(use_enable xinerama)
}
src_install() {
default
find "${D}" -name '*.la' -delete || die
dodoc HACKING MAINTAINERS *.txt doc/*.txt
}
src_test() {
virtx default
}
pkg_postinst() {
xdg_desktop_database_update
gnome2_schemas_update
}
pkg_postrm() {
xdg_desktop_database_update
gnome2_schemas_update
}
|
GitWeb