blob: 3c615b46d8cac262c5328f377167de1d69dca16c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools flag-o-matic multilib-minimal
DESCRIPTION="C library for executing name service queries asynchronously"
HOMEPAGE="http://0pointer.de/lennart/projects/libasyncns/"
SRC_URI="http://0pointer.de/lennart/projects/libasyncns/${P}.tar.gz"
SLOT="0"
LICENSE="LGPL-2.1"
KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ppc ppc64 ~sh sparc x86 ~amd64-linux ~x86-linux"
IUSE="doc debug"
BDEPEND="doc? ( app-doc/doxygen )"
src_prepare() {
default
# fix libdir in pkgconfig file
eapply "${FILESDIR}/${P}-libdir.patch"
# fix configure check for res_query
eapply "${FILESDIR}/${P}-configure-res_query.patch"
eautoreconf
}
multilib_src_configure() {
# libasyncns uses assert()
use debug || append-cppflags -DNDEBUG
ECONF_SOURCE=${S} \
econf \
--docdir="${EPREFIX}"/usr/share/doc/${PF} \
--htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
--disable-lynx \
--disable-static
}
multilib_src_compile() {
emake
if multilib_is_native_abi && use doc; then
doxygen doxygen/doxygen.conf || die "doxygen failed"
fi
}
multilib_src_install() {
default
if multilib_is_native_abi && use doc; then
docinto apidocs
dodoc -r html
fi
}
multilib_src_install_all() {
find "${D}" -name '*.la' -delete
}
|
GitWeb
