dev-perl/Parse-RecDescent/Parse-RecDescent-1.967.15.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6

DIST_AUTHOR=JTBRAUN
DIST_VERSION=1.967015
inherit perl-module

DESCRIPTION="Generate Recursive-Descent Parsers"

SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 ~sh sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="test examples"
RESTRICT="!test? ( test )"

RDEPEND="
	>=virtual/perl-Text-Balanced-1.950.0
"
DEPEND="${RDEPEND}
	dev-perl/Module-Build
	test? (
		virtual/perl-Test-Simple
		dev-perl/Test-Warn
	)
"
src_test() {
	perl_rm_files "t/pod.t"
	perl-module_src_test
}
src_install() {
	perl-module_src_install
	docinto html/
	dodoc -r tutorial
	if use examples; then
		docompress -x /usr/share/doc/${PF}/examples/
		docinto examples/
		dodoc -r demo/*
	fi
}