blob: 23c60db478037938f9be52a4cb26cde658aa6b8a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 2014-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python{2_7,3_{6,7}} )
inherit meson python-any-r1 udev
DESCRIPTION="Library to handle input devices in Wayland"
HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
LICENSE="MIT"
SLOT="0/10"
KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ppc ppc64 ~s390 sparc x86"
IUSE="doc input_devices_wacom"
# Tests require write access to udev rules directory which is a no-no for live system.
# Other tests are just about logs, exported symbols and autotest of the test library.
RESTRICT="test"
BDEPEND="
virtual/pkgconfig
doc? (
$(python_gen_any_dep '
dev-python/commonmark[${PYTHON_USEDEP}]
dev-python/recommonmark[${PYTHON_USEDEP}]
dev-python/sphinx[${PYTHON_USEDEP}]
>=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
')
>=app-doc/doxygen-1.8.3
>=media-gfx/graphviz-2.38.0
)
"
# test? ( dev-util/valgrind )
RDEPEND="
input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
>=dev-libs/libevdev-1.3
>=sys-libs/mtdev-1.1
virtual/libudev:=
virtual/udev
"
DEPEND="${RDEPEND}"
# test? ( >=dev-libs/check-0.9.10 )
python_check_deps() {
has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
}
pkg_setup() {
use doc && python-any-r1_pkg_setup
}
src_configure() {
# gui can be built but will not be installed
local emesonargs=(
-Ddebug-gui=false
$(meson_use doc documentation)
$(meson_use input_devices_wacom libwacom)
-Dtests=false # tests are restricted
-Dudev-dir="${EPREFIX}$(get_udevdir)"
)
meson_src_configure
}
src_install() {
meson_src_install
if use doc ; then
docinto html
dodoc -r "${BUILD_DIR}"/Documentation/.
fi
}
pkg_postinst() {
udevadm hwdb --update --root="${ROOT}"
}
|
GitWeb