blob: f54ae624af81e8e807bcd052814c3ebc8e8b1f90 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LLVM_MAX_SLOT=14
DISTUTILS_OPTIONAL=1
PYTHON_COMPAT=( python3_{9..11} )
inherit cmake distutils-r1 llvm
DESCRIPTION="assembly/assembler framework + bindings"
HOMEPAGE="https://www.keystone-engine.org/"
if [[ ${PV} == 9999* ]]; then
EGIT_REPO_URI="https://github.com/keystone-engine/keystone.git"
inherit git-r3
else
SRC_URI="https://github.com/keystone-engine/keystone/archive/${PV/_rc/-rc}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
fi
S="${WORKDIR}"/${P/_rc/-rc}
LICENSE="GPL-2"
SLOT="0"
# Keep in sync with llvm/CMakeLists.txt, subset of sys-devel/llvm
ALL_LLVM_TARGETS=( AArch64 ARM Hexagon Mips PowerPC Sparc SystemZ X86 )
ALL_LLVM_TARGETS=( "${ALL_LLVM_TARGETS[@]/#/llvm_targets_}" )
LLVM_TARGET_USEDEPS=${ALL_LLVM_TARGETS[@]/%/?}
IUSE="python ${ALL_LLVM_TARGETS[*]}"
RDEPEND="
<sys-devel/llvm-$((${LLVM_MAX_SLOT} + 1)):=[${LLVM_TARGET_USEDEPS// /,}]
python? ( ${PYTHON_DEPS} )
"
DEPEND="${RDEPEND}"
RESTRICT=test # only regression tests
REQUIRED_USE="
|| ( ${ALL_LLVM_TARGETS[*]} )
python? ( ${PYTHON_REQUIRED_USE} )
"
# Upstream doesn't flag patch releases (bug 858395)
QA_PKGCONFIG_VERSION="$(ver_cut 1-2)"
wrap_python() {
if use python; then
pushd bindings/python >/dev/null || die
distutils-r1_${1} "$@"
popd >/dev/null || die
fi
}
src_prepare() {
default
sed -i '/NOT uppercase_CMAKE_BUILD_TYPE MATCHES/ s/DEBUG/GENTOO|DEBUG/' \
llvm/CMakeLists.txt || die
cmake_src_prepare
wrap_python ${FUNCNAME}
}
src_configure() {
local libdir="$(get_libdir)"
local mycmakeargs=(
-DCMAKE_CONFIGURATION_TYPES="Gentoo"
-DLLVM_LIBDIR_SUFFIX=${libdir#lib}
-DBUILD_SHARED_LIBS=ON
-DLLVM_TARGETS_TO_BUILD="${LLVM_TARGETS// /;}"
-DLLVM_HOST_TRIPLE="${CHOST}"
)
cmake_src_configure
wrap_python ${FUNCNAME}
}
src_compile() {
cmake_src_compile
wrap_python ${FUNCNAME}
}
src_install() {
cmake_src_install
wrap_python ${FUNCNAME}
}
|
GitWeb