From 7c2cc60c49a29a761342eda64cede9e71898e2e1 Mon Sep 17 00:00:00 2001
From: Michael Mair-Keimberger <mmk@levelnine.at>
Date: Sun, 11 Feb 2024 18:34:48 +0100
Subject: sci-astronomy/wcstools: EAPI8 bump, fix SRC_URI, fix bug #849656

Signed-off-by: Michael Mair-Keimberger <mmk@levelnine.at>

Closes: https://bugs.gentoo.org/849656
Closes: https://github.com/gentoo/gentoo/pull/35279
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
---
 sci-astronomy/wcstools/wcstools-3.9.5-r1.ebuild | 67 +++++++++++++++++++++++++
 sci-astronomy/wcstools/wcstools-3.9.5.ebuild    | 67 -------------------------
 2 files changed, 67 insertions(+), 67 deletions(-)
 create mode 100644 sci-astronomy/wcstools/wcstools-3.9.5-r1.ebuild
 delete mode 100644 sci-astronomy/wcstools/wcstools-3.9.5.ebuild

(limited to 'sci-astronomy')

diff --git a/sci-astronomy/wcstools/wcstools-3.9.5-r1.ebuild b/sci-astronomy/wcstools/wcstools-3.9.5-r1.ebuild
new file mode 100644
index 000000000000..941a31e5f8e0
--- /dev/null
+++ b/sci-astronomy/wcstools/wcstools-3.9.5-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="World Coordinate System library for astronomical FITS images"
+HOMEPAGE="http://tdc-www.harvard.edu/software/wcstools/"
+SRC_URI="http://tdc-www.harvard.edu/software/wcstools/Old/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+
+DOCS=( Readme Programs NEWS )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.9.4-spelling.patch
+	"${FILESDIR}"/${PN}-3.9.4-haspm.patch
+	"${FILESDIR}"/${PN}-3.9.4-fix-tests.patch
+	"${FILESDIR}"/${PN}-3.9.4-compiler-warning.patch
+)
+
+src_prepare() {
+	default
+	einfo "Copying gentoo autotools files"
+	local f
+	for f in "${FILESDIR}"/{configure.ac,wcstools.pc.in,Makefile.am}; do
+		cp ${f} "${S}"/ || die
+	done
+	cp "${FILESDIR}"/Makefile.libwcs.am "${S}"/libwcs/Makefile.am || die
+	# avoid colliding with fixdos, getdate and remap from other packages
+	sed -i \
+		-e 's/getdate/wcsgetdate/' \
+		-e 's/crlf/wcscrlf/' \
+		-e 's/remap/wcsremap/' \
+		-e "s/3.... Programs/${PV} Programs/" \
+		wcstools || die
+	eautoreconf
+}
+
+src_test() {
+	einfo "Testing various wcstools programs"
+	./newfits -a 10 -j 248 41 -p 0.15 test.fits || die "test newfits failed"
+	./sethead test.fits A=1 B=1 ||  die "test sethead failed"
+	[[ "$(./gethead test.fits RA)" == "16:32:00.0000" ]] \
+		|| die "test gethead failed"
+	rm test.fits
+}
+
+src_install() {
+	default
+	doman man/man1/*
+	newdoc libwcs/NEWS NEWS.libwcs
+	newdoc libwcs/Readme Readme.libwcs
+
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	elog "The following execs have been renamed to avoid colliding"
+	elog "with other packages:"
+	elog " getdate -> wcsgetdate"
+	elog " crlf    -> wcscrlf"
+	elog " remap   -> wcsremap"
+}
diff --git a/sci-astronomy/wcstools/wcstools-3.9.5.ebuild b/sci-astronomy/wcstools/wcstools-3.9.5.ebuild
deleted file mode 100644
index 5bf03dd8cced..000000000000
--- a/sci-astronomy/wcstools/wcstools-3.9.5.ebuild
+++ /dev/null
@@ -1,67 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit autotools
-
-DESCRIPTION="World Coordinate System library for astronomical FITS images"
-HOMEPAGE="http://tdc-www.harvard.edu/software/wcstools"
-SRC_URI="http://tdc-www.harvard.edu/software/wcstools/${P}.tar.gz"
-
-LICENSE="GPL-2 LGPL-2.1"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
-IUSE=""
-
-DOCS=( Readme Programs NEWS )
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-3.9.4-spelling.patch
-	"${FILESDIR}"/${PN}-3.9.4-haspm.patch
-	"${FILESDIR}"/${PN}-3.9.4-fix-tests.patch
-	"${FILESDIR}"/${PN}-3.9.4-compiler-warning.patch
-)
-
-src_prepare() {
-	default
-	einfo "Copying gentoo autotools files"
-	local f
-	for f in "${FILESDIR}"/{configure.ac,wcstools.pc.in,Makefile.am}; do
-		cp ${f} "${S}"/ || die
-	done
-	cp "${FILESDIR}"/Makefile.libwcs.am "${S}"/libwcs/Makefile.am || die
-	# avoid colliding with fixdos, getdate and remap from other packages
-	sed -i \
-		-e 's/getdate/wcsgetdate/' \
-		-e 's/crlf/wcscrlf/' \
-		-e 's/remap/wcsremap/' \
-		-e "s/3.... Programs/${PV} Programs/" \
-		wcstools || die
-	eautoreconf
-}
-
-src_test() {
-	einfo "Testing various wcstools programs"
-	./newfits -a 10 -j 248 41 -p 0.15 test.fits || die "test newfits failed"
-	./sethead test.fits A=1 B=1 ||  die "test sethead failed"
-	[[ "$(./gethead test.fits RA)" == "16:32:00.0000" ]] \
-		|| die "test gethead failed"
-	rm test.fits
-}
-
-src_install() {
-	default
-	doman man/man1/*
-	newdoc libwcs/NEWS NEWS.libwcs
-	newdoc libwcs/Readme Readme.libwcs
-
-}
-
-pkg_postinst() {
-	elog "The following execs have been renamed to avoid colliding"
-	elog "with other packages:"
-	elog " getdate -> wcsgetdate"
-	elog " crlf    -> wcscrlf"
-	elog " remap   -> wcsremap"
-}
-- 
cgit v1.2.3-65-gdbad