From 82e6a754f111f9cdb82f33176332d7b392f23999 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Thu, 3 Nov 2022 06:16:56 +0000
Subject: media-libs/lcms: unconditionally enable threads

They're default on upstream.

Closes: https://bugs.gentoo.org/869740
Signed-off-by: Sam James <sam@gentoo.org>
---
 media-libs/lcms/lcms-2.14-r1.ebuild | 52 +++++++++++++++++++++++++++++++++++
 media-libs/lcms/lcms-2.14.ebuild    | 54 -------------------------------------
 2 files changed, 52 insertions(+), 54 deletions(-)
 create mode 100644 media-libs/lcms/lcms-2.14-r1.ebuild
 delete mode 100644 media-libs/lcms/lcms-2.14.ebuild

(limited to 'media-libs')

diff --git a/media-libs/lcms/lcms-2.14-r1.ebuild b/media-libs/lcms/lcms-2.14-r1.ebuild
new file mode 100644
index 000000000000..ecbc609f0e58
--- /dev/null
+++ b/media-libs/lcms/lcms-2.14-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="A lightweight, speed optimized color management engine"
+HOMEPAGE="http://www.littlecms.com/"
+SRC_URI="https://github.com/mm2/Little-CMS/releases/download/lcms${PV}/${PN}2-${PV}.tar.gz"
+S="${WORKDIR}/lcms2-${PV}"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc jpeg static-libs tiff zlib"
+REQUIRED_USE="tiff? ( zlib )"
+
+RDEPEND="
+	jpeg? ( media-libs/libjpeg-turbo:=[${MULTILIB_USEDEP}] )
+	tiff? ( >=media-libs/tiff-4.0.3-r6:=[${MULTILIB_USEDEP}] )
+	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# TODO: switch back to elibtoolize once https://github.com/mm2/Little-CMS/issues/339
+	# is fixed.
+	# for Prefix/Solaris
+	#elibtoolize
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-threads
+		$(use_with jpeg)
+		$(use_enable static-libs static)
+		$(use_with tiff)
+		$(use_with zlib)
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	use doc && dodoc doc/*.pdf
+}
diff --git a/media-libs/lcms/lcms-2.14.ebuild b/media-libs/lcms/lcms-2.14.ebuild
deleted file mode 100644
index 359754c152ef..000000000000
--- a/media-libs/lcms/lcms-2.14.ebuild
+++ /dev/null
@@ -1,54 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools multilib-minimal
-
-DESCRIPTION="A lightweight, speed optimized color management engine"
-HOMEPAGE="http://www.littlecms.com/"
-SRC_URI="https://github.com/mm2/Little-CMS/releases/download/lcms${PV}/${PN}2-${PV}.tar.gz"
-S="${WORKDIR}/lcms2-${PV}"
-
-LICENSE="MIT"
-SLOT="2"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-IUSE="doc jpeg static-libs test +threads tiff zlib"
-REQUIRED_USE="tiff? ( zlib )"
-
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	jpeg? ( media-libs/libjpeg-turbo:=[${MULTILIB_USEDEP}] )
-	tiff? ( >=media-libs/tiff-4.0.3-r6:=[${MULTILIB_USEDEP}] )
-	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
-"
-DEPEND="${RDEPEND}"
-
-src_prepare() {
-	default
-
-	# TODO: switch back to elibtoolize once https://github.com/mm2/Little-CMS/issues/339
-	# is fixed.
-	# for Prefix/Solaris
-	#elibtoolize
-	eautoreconf
-}
-
-multilib_src_configure() {
-	local myeconfargs=(
-		$(use_with jpeg)
-		$(use_enable static-libs static)
-		$(use_with threads)
-		$(use_with tiff)
-		$(use_with zlib)
-	)
-
-	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
-}
-
-multilib_src_install_all() {
-	find "${ED}" -type f -name "*.la" -delete || die
-
-	use doc && dodoc doc/*.pdf
-}
-- 
cgit v1.2.3-65-gdbad