From db5b4850fd48a33675977f8fdab6a320dcdd9500 Mon Sep 17 00:00:00 2001
From: David Roman <davidroman96@gmail.com>
Date: Tue, 2 Mar 2021 22:28:46 +0100
Subject: dev-vcs/git-cola: verbump to 3.9

Closes: https://bugs.gentoo.org/760582
Package-Manager: Portage-3.0.15, Repoman-3.0.2
Signed-off-by: David Roman <davidroman96@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/19743
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 dev-vcs/git-cola/Manifest            |   1 +
 dev-vcs/git-cola/git-cola-3.9.ebuild | 110 +++++++++++++++++++++++++++++++++++
 2 files changed, 111 insertions(+)
 create mode 100644 dev-vcs/git-cola/git-cola-3.9.ebuild

(limited to 'dev-vcs')

diff --git a/dev-vcs/git-cola/Manifest b/dev-vcs/git-cola/Manifest
index 3751edc0caa4..6a5e83767cc5 100644
--- a/dev-vcs/git-cola/Manifest
+++ b/dev-vcs/git-cola/Manifest
@@ -1,2 +1,3 @@
 DIST git-cola-3.5.tar.gz 970155 BLAKE2B ae602d4de0e6fac9d2817100bee8923d8f550d0bb83ddafd806ccdfbd0a77c65bfb60ff03a9399c6b60d5d4683eb6d46ee41eaa43faf2e2ac092b34c9151c999 SHA512 532e24092a72486171345aeb0e7610eb49c4062b64395988c6c4965cac6e9ffaed1268c30a0a525d4d99404f626d9e505a4be148d376994d4326e3ca873e2793
 DIST git-cola-3.8.tar.gz 980190 BLAKE2B 0502701c63f370b304a83094b2154757d1810216e82882472c7eac9633ac26eaa75974af05c32c18203d03b67a027655ea85c0e335915f204f668fcc86ed9c3f SHA512 9ae04dfef3b5bc64452a8df43e7afa93091f282097447208dadbd17522b62e5c43f7afce3eecc59fc4e38863496cdb41ac8b0453bbf327121629fbde20e45bb0
+DIST git-cola-3.9.tar.gz 992335 BLAKE2B ab591d953173aa69773a82eb91ebcc6fa5bc5e31efa78ad27f3e1e57e22c4222d70914f059dffb0b05b2b366d3208e127ad123ccfeb1b4c1b648daae0bf53352 SHA512 91f4bb40c166669e05136985920113d7482a396a46adf45fcf05e8ee56677fee7ebfb6a793face79737a17be42aa5e32b216a30847e8e4a5b8dc5b3b4eba5395
diff --git a/dev-vcs/git-cola/git-cola-3.9.ebuild b/dev-vcs/git-cola/git-cola-3.9.ebuild
new file mode 100644
index 000000000000..11cb88f55b7f
--- /dev/null
+++ b/dev-vcs/git-cola/git-cola-3.9.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_SINGLE_IMPL=true
+DISTUTILS_USE_SETUPTOOLS=no
+inherit distutils-r1 readme.gentoo-r1 virtualx xdg-utils
+
+DESCRIPTION="The highly caffeinated git GUI"
+HOMEPAGE="https://git-cola.github.io/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/numpy[${PYTHON_MULTI_USEDEP}]
+		dev-python/pygments[${PYTHON_MULTI_USEDEP}]
+		dev-python/PyQt5[network,${PYTHON_USEDEP}]
+		dev-python/QtPy[gui,${PYTHON_MULTI_USEDEP}]
+		dev-python/send2trash[${PYTHON_MULTI_USEDEP}]
+	')
+	dev-vcs/git
+"
+BDEPEND="sys-devel/gettext
+	$(python_gen_cond_dep "
+		doc? ( dev-python/sphinx[\${PYTHON_MULTI_USEDEP}] )
+		test? (
+			${VIRTUALX_DEPEND}
+			dev-python/mock[\${PYTHON_MULTI_USEDEP}]
+			dev-python/nose[\${PYTHON_MULTI_USEDEP}]
+			dev-python/pytest[\${PYTHON_MULTI_USEDEP}]
+		)
+	")
+"
+
+python_prepare_all() {
+	# make sure that tests also use the system provided QtPy
+	rm -r qtpy || die
+
+	rm share/git-cola/bin/*askpass* || die
+
+	# don't install docs into wrong location
+	sed -i -e '/doc/d' setup.py || die
+
+	# fix doc directory reference
+	sed -i \
+		-e "s/'doc', 'git-cola'/'doc', '${PF}'/" \
+		cola/resources.py || die
+
+	# fix ssh-askpass directory reference
+	sed -i -e 's/resources\.share/resources\.prefix/' cola/app.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	mydistutilsargs=( --no-vendor-libs --no-private-libs )
+}
+
+python_compile_all() {
+	cd share/doc/${PN}/ || die
+	if use doc ; then
+		emake all
+	else
+		sed \
+			-e '/^install:/s:install-html::g' \
+			-e '/^install:/s:install-man::g' \
+			-i Makefile || die
+	fi
+}
+
+python_test() {
+	GIT_CONFIG_NOSYSTEM=true \
+	PYTHONPATH="${S}:${S}/build/lib:${PYTHONPATH}" LC_ALL="C.utf8" \
+	virtx nosetests --verbose --with-id --with-doctest \
+		--exclude=sphinxtogithub
+}
+
+python_install_all() {
+	cd share/doc/${PN}/ || die
+	emake \
+		DESTDIR="${D}" \
+		docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		prefix="${EPREFIX}/usr" \
+		install
+
+	# remove empty bin folder
+	rm -R "${ED}"/usr/share/git-cola/bin || die
+
+	use doc || HTML_DOCS=( "${FILESDIR}"/index.html )
+
+	distutils-r1_python_install_all
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3-65-gdbad