From 0320a5d61c04de62c40029900f95b7bbcc170673 Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Sat, 11 Mar 2017 10:39:59 +0100
Subject: dev-vcs/qct: Fix python, EAPI 6

Package-Manager: Portage-2.3.4, Repoman-2.3.2
---
 dev-vcs/qct/qct-1.7-r1.ebuild | 71 -------------------------------------------
 dev-vcs/qct/qct-1.7-r2.ebuild | 71 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+), 71 deletions(-)
 delete mode 100644 dev-vcs/qct/qct-1.7-r1.ebuild
 create mode 100644 dev-vcs/qct/qct-1.7-r2.ebuild

(limited to 'dev-vcs')

diff --git a/dev-vcs/qct/qct-1.7-r1.ebuild b/dev-vcs/qct/qct-1.7-r1.ebuild
deleted file mode 100644
index f87df10dae1d..000000000000
--- a/dev-vcs/qct/qct-1.7-r1.ebuild
+++ /dev/null
@@ -1,71 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-
-PYTHON_COMPAT=( python2_7 )
-DISTUTILS_SINGLE_IMPL=1
-
-inherit distutils-r1
-
-DESCRIPTION="PyQt based commit tool for many VCSs"
-HOMEPAGE="http://qct.sourceforge.net/"
-SRC_URI="http://qct.sourceforge.net/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="bazaar cvs mercurial monotone subversion"
-
-DEPEND="app-text/asciidoc[${PYTHON_USEDEP}]
-	app-text/xmlto
-	dev-python/PyQt4[${PYTHON_USEDEP}]
-	bazaar? ( dev-vcs/bzr[${PYTHON_USEDEP}] )
-	cvs? ( dev-vcs/cvs )
-	mercurial? ( dev-vcs/mercurial[${PYTHON_USEDEP}] )
-	monotone? ( dev-vcs/monotone )
-	subversion? ( dev-vcs/subversion[${PYTHON_USEDEP}] )"
-RDEPEND="${DEPEND}"
-
-S="${WORKDIR}/${PN}"
-
-pkg_setup() {
-	python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	rm qctlib/vcs/p4.py
-
-	# support for git requires cogito which isn't in portage
-	rm qctlib/vcs/git.py
-	rm qctlib/vcs/cg.py
-
-	use bazaar || rm qctlib/vcs/bzr.py
-	use cvs || rm qctlib/vcs/cvs.py
-	use mercurial || rm qctlib/vcs/hg.py
-	use monotone || rm qctlib/vcs/mtn.py
-	use subversion || rm qctlib/vcs/svn.py
-}
-
-src_install() {
-	distutils-r1_src_install
-
-	# manpage and html docs are built using asciidoc
-	make -C doc man html || die
-	doman doc/qct.1 || die
-	dohtml doc/qct.1.html || die
-
-	if use bazaar; then
-		insinto "$(python_get_sitedir)/bzrlib/plugins"
-		doins plugins/qctBzrPlugin.py
-	fi
-
-	if use mercurial; then
-		insinto "$(python_get_sitedir)/hgext"
-		doins hgext/qct.py
-		insinto /etc/mercurial/hgrc.d
-		doins "${FILESDIR}/qct.rc"
-	fi
-}
diff --git a/dev-vcs/qct/qct-1.7-r2.ebuild b/dev-vcs/qct/qct-1.7-r2.ebuild
new file mode 100644
index 000000000000..0093c1bb1ff4
--- /dev/null
+++ b/dev-vcs/qct/qct-1.7-r2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1
+
+DESCRIPTION="PyQt based commit tool for many VCSs"
+HOMEPAGE="http://qct.sourceforge.net/"
+SRC_URI="http://qct.sourceforge.net/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bazaar cvs mercurial monotone subversion"
+
+DEPEND="
+	app-text/asciidoc
+	app-text/xmlto
+	dev-python/PyQt4[${PYTHON_USEDEP}]
+	bazaar? ( dev-vcs/bzr[${PYTHON_USEDEP}] )
+	cvs? ( dev-vcs/cvs )
+	mercurial? ( dev-vcs/mercurial[${PYTHON_USEDEP}] )
+	monotone? ( dev-vcs/monotone )
+	subversion? ( dev-vcs/subversion[${PYTHON_USEDEP}] )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+python_prepare_all() {
+	# support for git requires cogito which isn't in portage
+	rm qctlib/vcs/{p4,git,cg}.py || die
+
+	declare -A delfiles=([bazaar]=bzr [cvs]=cvs [mercurial]=hg [monotone]=mtn [subversion]=svn)
+	local i
+	for i in "${!delfiles[@]}"; do
+		if ! use $i; then
+			rm qctlib/vcs/${delfiles[$i]}.py || die
+		fi
+	done
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# manpage and html docs are built using asciidoc
+	emake -C doc man html
+	HTML_DOCS=( doc/qct.1.html )
+}
+
+python_install_all() {
+	doman doc/qct.1
+
+	if use bazaar; then
+		python_moduleinto bzrlib/plugins
+		python_domodule plugins/qctBzrPlugin.py
+	fi
+
+	if use mercurial; then
+		python_moduleinto hgext
+		python_domodule hgext/qct.py
+
+		insinto /etc/mercurial/hgrc.d
+		doins "${FILESDIR}/qct.rc"
+	fi
+
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad