From a14e2c5e0f721c65399b332b0159ffde0323f29c Mon Sep 17 00:00:00 2001
From: Maciej Barć <xgqt@gentoo.org>
Date: Tue, 26 Dec 2023 21:57:16 +0100
Subject: dev-util/shards: bump to 0.17.4
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Maciej Barć <xgqt@gentoo.org>
---
 dev-util/shards/Manifest             |  1 +
 dev-util/shards/shards-0.17.4.ebuild | 56 ++++++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)
 create mode 100644 dev-util/shards/shards-0.17.4.ebuild

(limited to 'dev-util')

diff --git a/dev-util/shards/Manifest b/dev-util/shards/Manifest
index 78275916567f..727cfebab52c 100644
--- a/dev-util/shards/Manifest
+++ b/dev-util/shards/Manifest
@@ -1,2 +1,3 @@
 DIST crystal-molinillo-0.2.0.tar.gz 23959 BLAKE2B 257dcca66583db87a802b27b1f100e226eb0b6ac53708d110040d7b5560f429a82f11595e303af4922f22917d922d60ea380fb395d254dc3b3ce24f4183395b6 SHA512 7c00a6a3ee4864b712ad8b703557f10498ba0b25491a55ae2f6c02d574034ec5bf8b87df777c3d34eb9cc4c87eebdcf6567c153e9edf3bc3c1b9ac4306ce3dc2
 DIST shards-0.17.3.tar.gz 72539 BLAKE2B 2be15469df4b8a53ebd480815487f782717ce9d436cddf6acc2559e4c5dd61f06a1089d34b0a31aab2ab3e5334cd10abe513edd2cbe92b84d0fbd1cfc6cb09e5 SHA512 0789cf1fcc0df0f2d7657c034a157f05c0d65ee2c2ecda1f3d8b2d2f1274d584769f8600985fc463bc6632fe0a0822bdc40250aef2a92d1d612d0548ed0f4d2a
+DIST shards-0.17.4.tar.gz 73231 BLAKE2B 8480d6a56fadf1dfac44262fe260365f910ba8004f2361cae5646c2fa77a0e71c46b91c9a707e7b3825ed94a31eb94dc43d16b6d7e1da5efcc52a22ea39a51bb SHA512 82c7f2e4bb9b280a49cfb1a0468b2fe0a551d55b91b74e01d50478ff3b2652b872b225a345f8f7816f5130141603baad96387df2b0df45e7ec79c2d47956c011
diff --git a/dev-util/shards/shards-0.17.4.ebuild b/dev-util/shards/shards-0.17.4.ebuild
new file mode 100644
index 000000000000..013d311a44fe
--- /dev/null
+++ b/dev-util/shards/shards-0.17.4.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multiprocessing toolchain-funcs
+
+CRYSTAL_MOLINILLO_PV=0.2.0
+CRYSTAL_MOLINILLO_P=crystal-molinillo-${CRYSTAL_MOLINILLO_PV}
+
+DESCRIPTION="Dependency manager for the Crystal language"
+HOMEPAGE="https://github.com/crystal-lang/shards/"
+SRC_URI="
+	https://github.com/crystal-lang/shards/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+	https://github.com/crystal-lang/crystal-molinillo/archive/v${CRYSTAL_MOLINILLO_PV}.tar.gz
+		-> ${CRYSTAL_MOLINILLO_P}.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+RESTRICT="test"  # missing files in tarball
+
+RDEPEND="
+	>dev-lang/crystal-0.11.1
+	dev-libs/libyaml:=
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( CHANGELOG.md README.md SPEC.md )
+
+QA_PREBUILT=".*"  # Generated by Crystal.
+
+src_prepare() {
+	default
+
+	# bundle crystal-molinillo to bootstrap 'shards'
+	mkdir -p lib || die
+	ln -s ../../${CRYSTAL_MOLINILLO_P} lib/molinillo || die
+
+	tc-export CC
+}
+
+src_compile() {
+	emake release=1 \
+		FLAGS="--link-flags=\"${LDFLAGS}\" --verbose --threads $(makeopts_jobs)"
+}
+
+src_install() {
+	exeinto /usr/bin
+	doexe bin/${PN}
+
+	doman man/*
+	einstalldocs
+}
-- 
cgit v1.2.3-65-gdbad