From 1cc3a1ad5bd3681ef1223188b3dbffb4cbfa7fe6 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Thu, 6 May 2021 09:57:46 +0200
Subject: dev-python/tox: Bump to 3.23.1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/tox/Manifest          |  1 +
 dev-python/tox/tox-3.23.1.ebuild | 74 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)
 create mode 100644 dev-python/tox/tox-3.23.1.ebuild

(limited to 'dev-python/tox')

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 67828445f2a6..1865b4af5f74 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1 +1,2 @@
 DIST tox-3.23.0.tar.gz 303091 BLAKE2B 609e74ea354ca5daf45c848000961782fcef59da07f815292355d72f3e5dd078e3b5909a65521a4a1032fa2bb9481fdab0e620f4882b33aa377de9764296761c SHA512 fb96cbbdbd36399036d348716f1181285184985922e0dc61b610b36e53ea79e2d8a77190aad893650bcba86ef4c57ff0f2de2813becb2a12fe0d1aa36bb27ad3
+DIST tox-3.23.1.tar.gz 303896 BLAKE2B d59160035a6412a69f9434bfb5b2b27aa9a2ebd5344b4898b677dac15dc91ab94feca67b8edde4c0ba68c8a6a12fa885091d82a088439257e9393a99e77ade88 SHA512 ec5daf106287b265d1abec8465df8ad053ecf59876038a7cb419a57e22373809e50f8131736762dc485f559363b1878abb49d909e7b6952b2e49eea77c193281
diff --git a/dev-python/tox/tox-3.23.1.ebuild b/dev-python/tox/tox-3.23.1.ebuild
new file mode 100644
index 000000000000..938612131f77
--- /dev/null
+++ b/dev-python/tox/tox-3.23.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="https://tox.readthedocs.io https://github.com/tox-dev/tox https://pypi.org/project/tox/"
+SRC_URI="https://github.com/tox-dev/tox/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+# doc disabled because of missing deps in tree
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/filelock[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-1.1[${PYTHON_USEDEP}]
+	' python3_{5,6,7} pypy3)
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/py[${PYTHON_USEDEP}]
+	>=dev-python/six-1.14[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]"
+# TODO: figure out how to make tests work without the package being
+# installed first.
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/flaky-3.4.0[${PYTHON_USEDEP}]
+		>=dev-python/freezegun-0.3.11[${PYTHON_USEDEP}]
+		>=dev-python/pytest-4.0.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)"
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local deselect=(
+		# broken without Internet
+		tests/unit/session/test_provision.py::test_provision_non_canonical_dep
+		tests/integration/test_provision_int.py::test_provision_interrupt_child
+
+		# expects python2 to exist
+		tests/unit/interpreters/test_interpreters.py::test_tox_get_python_executable
+
+		# broken without tox installed first
+		# TODO: figure out how to make importlib_metadata work
+		tests/unit/test_z_cmdline.py::test_tox_console_script
+		tests/unit/test_z_cmdline.py::test_tox_quickstart_script
+	)
+
+	[[ ${EPYTHON} != pypy3 ]] && deselect+=(
+		# TODO?
+		tests/unit/interpreters/test_interpreters.py::test_find_alias_on_path
+
+		# broken without tox installed first
+		# TODO: why it can't import itself?
+		tests/integration/test_parallel_interrupt.py::test_parallel_interrupt
+	)
+
+	distutils_install_for_testing --via-root
+	epytest --no-network ${deselect[@]/#/--deselect }
+}
-- 
cgit v1.2.3-65-gdbad