From cc3811adf78b83af1cc2e27a893eae26fc9fc8ad Mon Sep 17 00:00:00 2001
From: Tiziano Müller <dev-zero@gentoo.org>
Date: Sun, 6 Nov 2016 11:59:17 +0100
Subject: dev-python/flask-babelex: initial commit, required for (testing)
 Flask-Admin

Package-Manager: portage-2.3.0
---
 .../flask-babelex/flask-babelex-0.9.3.ebuild       | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 dev-python/flask-babelex/flask-babelex-0.9.3.ebuild

(limited to 'dev-python/flask-babelex/flask-babelex-0.9.3.ebuild')

diff --git a/dev-python/flask-babelex/flask-babelex-0.9.3.ebuild b/dev-python/flask-babelex/flask-babelex-0.9.3.ebuild
new file mode 100644
index 000000000000..2a3b9ac45609
--- /dev/null
+++ b/dev-python/flask-babelex/flask-babelex-0.9.3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+
+inherit distutils-r1
+
+MY_PN="Flask-BabelEx"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Adds i18n/l10n support to Flask applications"
+HOMEPAGE="http://github.com/mrjoes/flask-babelex https://pypi.python.org/pypi/Flask-BabelEx"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
+	>=dev-python/Babel-1[${PYTHON_USEDEP}]
+	>=dev-python/speaklater-1.2[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.5[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/flask-sphinx-themes[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}/${P}-tests-fix.patch" )
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	cd tests || die
+	"${PYTHON}" tests.py || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad