From 7cc6305b5faf7ca2226b3400cd76dead387c0afb Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Thu, 30 May 2024 04:20:56 +0100
Subject: dev-libs/zziplib: add 0.13.76

Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-libs/zziplib/Manifest               |  1 +
 dev-libs/zziplib/zziplib-0.13.76.ebuild | 70 +++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)
 create mode 100644 dev-libs/zziplib/zziplib-0.13.76.ebuild

(limited to 'dev-libs')

diff --git a/dev-libs/zziplib/Manifest b/dev-libs/zziplib/Manifest
index 818ead106f53..0e48fca0f0ca 100644
--- a/dev-libs/zziplib/Manifest
+++ b/dev-libs/zziplib/Manifest
@@ -1,3 +1,4 @@
 DIST zziplib-0.13.72.tar.gz 1162175 BLAKE2B ff5617645e25040e4666e5440651fbb2b04c0505c7bda08b158f44c63c5dd53ec97a9942908314c3b103a4685be49368e964d249fcf9b9d685e328f0ebabdedd SHA512 4bb089e74813c6fac9657cd96e44e4a6469bf86aba3980d885c4573e8db45e74fd07bbdfcec9f36297c72227c8c0b2c37dab1bc4326cef8529960e482fe501c8
 DIST zziplib-0.13.74-testdata.tar.xz 166188 BLAKE2B f3cc98495542fb95e8bd9cfb98ecd22c9e6206fd13c1d0607ee8b7640ddb3d3c4b9cb7bc7ca7a95a787ffef4e5a8c2b4ab1bc0c5890811ab21c681239840dcdb SHA512 d4545f770c4f00658ec69a7f393f38d0c649704adb30b6a25f2c0b48711829416985258d34911d48b9bd394d9334ab89c8deda719f2aae509a75441f8a8d8902
 DIST zziplib-0.13.74.tar.gz 1177162 BLAKE2B fc093b731406101086e59ff54b4378190c88821c4349d75e35c9595b45695b5f91a20e99a9689f7ebbc8d8951f2c4e1132d670e3827f5329977de1f85c9ce5d2 SHA512 7dd27247cbc475e2c6beb3a96c620f9938ade0dff6f4e088f9c28432fc4cc01df9d6771ec3d5e07baabe27033f4764d60e31c4c54588559de64e894d0557c94f
+DIST zziplib-0.13.76.tar.gz 1185716 BLAKE2B c04743fc47e6a0e102a01d0473d88b9f9cb044a3a021119d16533949d0a1f132fb73f957714a840b0474590bc98f62132e89ce890c5c9097a77d8f007c3f1e5a SHA512 d4b327530fc2681df1705b24d5de697d3c3829e299c28e047849444c7aeaf87e188d96782a2009dc7ae216f82f744a32a94fc7962fb12b3a62b28d7ecf12a7d6
diff --git a/dev-libs/zziplib/zziplib-0.13.76.ebuild b/dev-libs/zziplib/zziplib-0.13.76.ebuild
new file mode 100644
index 000000000000..cef1f31dd237
--- /dev/null
+++ b/dev-libs/zziplib/zziplib-0.13.76.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+# Needed for docs, bug #835755
+PYTHON_REQ_USE="xml(+)"
+inherit cmake flag-o-matic python-any-r1
+
+TEST_PV="0.13.74"
+DESCRIPTION="Lightweight library for extracting data from files archived in a single zip file"
+HOMEPAGE="https://github.com/gdraheim/zziplib https://zziplib.sourceforge.net"
+# Test data tarball generated with python ./zziptests.py -D -d /tmp/zziplib -v
+SRC_URI="
+	https://github.com/gdraheim/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	test? ( https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${PN}-${TEST_PV}-testdata.tar.xz )
+"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0/13"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="sdl test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	test? (
+		app-arch/unzip
+		app-arch/zip
+	)
+"
+DEPEND="
+	sys-libs/zlib
+	sdl? ( >=media-libs/libsdl-1.2.6 )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# This test assumes being built with automake (checks for .libs/x).
+	sed -i -e 's/test_91000_zzshowme_check_sfx/skip_&/' test/zziptests.py || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	# https://github.com/gdraheim/zziplib/commit/f3bfc0dd6663b7df272cc0cf17f48838ad724a2f#diff-b7b1e314614cf326c6e2b6eba1540682R100
+	append-flags -fno-strict-aliasing
+
+	local mycmakeargs=(
+		-DZZIPSDL=$(usex sdl)
+		-DBUILD_TESTS=$(usex test)
+		-DZZIPTEST=$(usex test)
+		-DZZIPDOCS=ON
+		-DZZIPWRAP=OFF
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${S}" || die
+	"${EPYTHON}" "${S}"/test/zziptests.py \
+		--downloads=no \
+		--verbose \
+		--topsrcdir "${S}" \
+		--bindir "$(realpath --relative-to="${S}" "${BUILD_DIR}"/bins)" \
+		--downloaddir "${WORKDIR}"/${PN}-${TEST_PV}-testdata \
+		--testdatadir "${T}"/testdata.d \
+	|| die "Tests failed with ${EPYTHON}"
+}
-- 
cgit v1.2.3-65-gdbad