From 54e47dba180ae292a9e51370ca2c9cc52df993a2 Mon Sep 17 00:00:00 2001
From: Viorel Munteanu <ceamac@gentoo.org>
Date: Fri, 8 Dec 2023 20:08:17 +0200
Subject: app-misc/fastfetch: add 2.3.4

Bug: https://bugs.gentoo.org/916054
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
---
 app-misc/fastfetch/Manifest               |   1 +
 app-misc/fastfetch/fastfetch-2.3.4.ebuild | 113 ++++++++++++++++++++++++++++++
 2 files changed, 114 insertions(+)
 create mode 100644 app-misc/fastfetch/fastfetch-2.3.4.ebuild

(limited to 'app-misc')

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 0e79c09b5e0a..4774ce6d9818 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,3 +1,4 @@
 DIST fastfetch-1.12.2.tar.gz 538194 BLAKE2B bc6badbc7f690dacbe1408479286a0d42ec687526f776ff4d2ec7b0eb767032e5781cbbe37778f4dc03a5d386979a9ae2aab84c466be997b82d9a9a6c81ea78f SHA512 a82a7c7ae365335c20d659a82215cf320c4c6b07ff127c4dad322a0a01f7ec57e34d229f4953108daadcd0d243c84f8504a3b4367df5e255e5a06e685fd6739a
 DIST fastfetch-2.2.3.tar.gz 901203 BLAKE2B d6d097b72ce2f252e42b3e59cbd26b43a4f17ae974382f986270fbf91b457cf3c49e78a3c775e713d9302d536fb5a363e809005b9174d1a27622e6b6ed666709 SHA512 81e051b7555d56415c723606c0b6dfc3ad7ed91fb2c7b36c07465f4dfbdb91da5c8d216e46df36863888448de0a7bd63e28c6aa701995bf1165e0d7c33c4f724
 DIST fastfetch-2.3.3.tar.gz 909014 BLAKE2B 70cde268130bcd979b5b472f231ea7f4f14fe68472c6a92ba31eb6a8c4b2ff1b4bb4c13cb2a3c567b72aa57b9eb616518baa6322184c131d8bd3d7a3a11b97db SHA512 8d44b94df522f41e64e266a54824769a4588de7e07846f461554981886d058c3bba23df017b8619eb376de9dcd926462bcdda3fb6f0770f83f60a3ad96cb7e85
+DIST fastfetch-2.3.4.tar.gz 909105 BLAKE2B 132f88681f9133cdeae8126c4dabf4e8805865fe506a005f938bcda487750a874ab59deebdf2fc348c2a469cf4771fe5916f594a5a408769c1e49fba417ab113 SHA512 fe1e6465380e513e4e75092bc737b23adca4c9dd42de8adb888bad1ce173f1fa9c93e9cbd7b2ca648058503b7cfb72c2ba1d70abf63b8f1497e94ce6eb349524
diff --git a/app-misc/fastfetch/fastfetch-2.3.4.ebuild b/app-misc/fastfetch/fastfetch-2.3.4.ebuild
new file mode 100644
index 000000000000..4af72e9b74c7
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.3.4.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm gnome imagemagick networkmanager opencl opengl osmesa pci pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.8.0:=
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	networkmanager? ( net-misc/networkmanager )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pci? ( sys-apps/pciutils )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_LIBNM=$(usex networkmanager)
+		-DENABLE_LIBPCI=$(usex pci)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	rm -r "${ED}"/usr/share/licenses || die
+}
-- 
cgit v1.2.3-65-gdbad