From 4f739c6d4fbffd43da74389b7939949e15a916da Mon Sep 17 00:00:00 2001
From: Arthur Zamarin <arthurzam@gentoo.org>
Date: Thu, 11 Apr 2024 18:06:33 +0300
Subject: app-i18n/kanjipad: EAPI8, add missing RDEPs

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
---
 app-i18n/kanjipad/kanjipad-2.0.0-r1.ebuild | 52 ++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 app-i18n/kanjipad/kanjipad-2.0.0-r1.ebuild

(limited to 'app-i18n')

diff --git a/app-i18n/kanjipad/kanjipad-2.0.0-r1.ebuild b/app-i18n/kanjipad/kanjipad-2.0.0-r1.ebuild
new file mode 100644
index 000000000000..2f20eacc9b1c
--- /dev/null
+++ b/app-i18n/kanjipad/kanjipad-2.0.0-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Japanese handwriting recognition tool"
+HOMEPAGE="https://fishsoup.net/software/kanjipad/"
+SRC_URI="https://fishsoup.net/software/kanjipad/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+RDEPEND="
+	app-accessibility/at-spi2-core:2
+	x11-libs/gtk+:2
+	dev-libs/glib:2
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${P}-cflags.patch"
+	"${FILESDIR}/${P}-underlinking.patch"
+)
+
+src_prepare() {
+	default
+	sed -i -e "s|PREFIX=/usr/local|PREFIX=/usr|" \
+		-e "s|-DG.*DISABLE_DEPRECATED||g" Makefile || die "Fixing Makefile failed"
+}
+
+src_configure() {
+	tc-export CC
+}
+
+src_install() {
+	dobin kanjipad kpengine
+	insinto /usr/share/kanjipad
+	doins jdata.dat
+
+	local DOCS=( ChangeLog README TODO jstroke/README-kanjipad )
+	einstalldocs
+}
-- 
cgit v1.2.3-65-gdbad