From ae3ce150147db89f124274ae961d5c37a87a0040 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sun, 19 Feb 2017 23:17:05 +0100
Subject: www-apps/viewvc: python-single-r1, EAPI=6

---
 www-apps/viewvc/viewvc-1.1.20-r1.ebuild | 114 ++++++++++++++++++++++++++++++
 www-apps/viewvc/viewvc-1.1.20.ebuild    | 120 --------------------------------
 2 files changed, 114 insertions(+), 120 deletions(-)
 create mode 100644 www-apps/viewvc/viewvc-1.1.20-r1.ebuild
 delete mode 100644 www-apps/viewvc/viewvc-1.1.20.ebuild

diff --git a/www-apps/viewvc/viewvc-1.1.20-r1.ebuild b/www-apps/viewvc/viewvc-1.1.20-r1.ebuild
new file mode 100644
index 000000000000..f1e18653d540
--- /dev/null
+++ b/www-apps/viewvc/viewvc-1.1.20-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit confutils eutils python-single-r1 webapp
+
+WEBAPP_MANUAL_SLOT="yes"
+
+DESCRIPTION="ViewVC, a web interface to CVS and Subversion"
+HOMEPAGE="http://viewvc.org/"
+DOWNLOAD_NUMBER="49275"
+SRC_URI="http://viewvc.tigris.org/files/documents/3330/${DOWNLOAD_NUMBER}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="amd64 ~ppc x86"
+IUSE="cvs cvsgraph mod_wsgi mysql pygments +subversion"
+
+DEPEND=""
+RDEPEND="${PYTHON_DEPS}
+	cvs? ( dev-vcs/rcs )
+	subversion? ( >=dev-vcs/subversion-1.3.1[python,${PYTHON_USEDEP}] )
+
+	mod_wsgi? ( www-apache/mod_wsgi[${PYTHON_USEDEP}] )
+	!mod_wsgi? ( virtual/httpd-cgi )
+
+	cvsgraph? ( >=dev-vcs/cvsgraph-1.5.0 )
+	mysql? ( >=dev-python/mysql-python-0.9.0[${PYTHON_USEDEP}] )
+	pygments? (
+		dev-python/pygments[${PYTHON_USEDEP}]
+		app-misc/mime-types
+	)
+"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	webapp_pkg_setup
+
+	confutils_require_any cvs subversion
+}
+
+src_prepare() {
+	eapply_user
+
+	find bin/ -type f -print0 | xargs -0 sed -i \
+		-e "s|\(^LIBRARY_DIR\)\(.*\$\)|\1 = \"$(python_get_sitedir)/${PN}\"|g" \
+		-e "s|\(^CONF_PATHNAME\)\(.*\$\)|\1 = \"../conf/viewvc.conf\"|g" || die
+
+	sed -i -e "s|\(self\.options\.template_dir\)\(.*\$\)|\1 = \"${MY_APPDIR}/templates\"|" \
+		lib/config.py || die
+
+	sed -i -e "s|^template_dir.*|#&|" conf/viewvc.conf.dist || die
+	sed -i -e "s|^#mime_types_files =.*|mime_types_files = /etc/mime.types|" conf/viewvc.conf.dist || die
+	mv conf/viewvc.conf{.dist,} || die
+	mv conf/cvsgraph.conf{.dist,} || die
+
+	python_fix_shebang .
+}
+
+src_install() {
+	webapp_src_preinst
+
+	newbin bin/standalone.py viewvc-standalone-server
+
+	dodoc CHANGES COMMITTERS INSTALL README
+
+	python_moduleinto viewvc
+	python_domodule lib/.
+
+	insinto "${MY_APPDIR}"
+	doins -r templates/ || die "doins failed"
+	doins -r templates-contrib/
+
+	if use mysql; then
+		exeinto "${MY_HOSTROOTDIR}/bin"
+		doexe bin/{*dbadmin,make-database,loginfo-handler}
+	fi
+
+	insinto "${MY_HOSTROOTDIR}/conf"
+	doins conf/{viewvc,cvsgraph}.conf
+
+	exeinto "${MY_CGIBINDIR}"
+	doexe bin/cgi/viewvc.cgi
+	if use mysql; then
+		doexe bin/cgi/query.cgi
+	fi
+
+	exeinto "${MY_CGIBINDIR}"
+	if use mod_wsgi; then
+		doexe bin/wsgi/viewvc.wsgi
+		if use mysql; then
+			doexe bin/wsgi/query.wsgi
+		fi
+	else
+		doexe bin/wsgi/viewvc.fcgi
+		if use mysql; then
+			doexe bin/wsgi/query.fcgi
+		fi
+	fi
+
+	webapp_configfile "${MY_HOSTROOTDIR}/conf/"{viewvc,cvsgraph}.conf
+
+	webapp_src_install
+}
+
+pkg_postinst() {
+	webapp_pkg_postinst
+	elog "Now read INSTALL in /usr/share/doc/${PF} to configure ${PN}"
+}
diff --git a/www-apps/viewvc/viewvc-1.1.20.ebuild b/www-apps/viewvc/viewvc-1.1.20.ebuild
deleted file mode 100644
index a72a8da78680..000000000000
--- a/www-apps/viewvc/viewvc-1.1.20.ebuild
+++ /dev/null
@@ -1,120 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI="5"
-PYTHON_DEPEND="2"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="3.* *-jython"
-
-inherit confutils eutils python webapp
-
-WEBAPP_MANUAL_SLOT="yes"
-
-DESCRIPTION="ViewVC, a web interface to CVS and Subversion"
-HOMEPAGE="http://viewvc.org/"
-DOWNLOAD_NUMBER="49275"
-SRC_URI="http://viewvc.tigris.org/files/documents/3330/${DOWNLOAD_NUMBER}/${P}.tar.gz"
-
-LICENSE="BSD-2"
-SLOT="0"
-KEYWORDS="amd64 ~ppc x86"
-IUSE="cvs cvsgraph mod_wsgi mysql pygments +subversion"
-
-DEPEND=""
-RDEPEND="
-	cvs? ( dev-vcs/rcs )
-	subversion? ( >=dev-vcs/subversion-1.3.1[python] )
-
-	mod_wsgi? ( www-apache/mod_wsgi )
-	!mod_wsgi? ( virtual/httpd-cgi )
-
-	cvsgraph? ( >=dev-vcs/cvsgraph-1.5.0 )
-	mysql? ( >=dev-python/mysql-python-0.9.0 )
-	pygments? (
-		dev-python/pygments
-		app-misc/mime-types
-	)
-"
-
-pkg_setup() {
-	python_pkg_setup
-	webapp_pkg_setup
-
-	confutils_require_any cvs subversion
-}
-
-src_prepare() {
-	find bin/ -type f -print0 | xargs -0 sed -i \
-		-e "s|\(^LIBRARY_DIR\)\(.*\$\)|\1 = \"$(python_get_sitedir -f)/${PN}\"|g" \
-		-e "s|\(^CONF_PATHNAME\)\(.*\$\)|\1 = \"../conf/viewvc.conf\"|g"
-
-	sed -i -e "s|\(self\.options\.template_dir\)\(.*\$\)|\1 = \"${MY_APPDIR}/templates\"|" \
-		lib/config.py
-
-	sed -i -e "s|^template_dir.*|#&|" conf/viewvc.conf.dist
-	sed -i -e "s|^#mime_types_files =.*|mime_types_files = /etc/mime.types|" conf/viewvc.conf.dist
-	mv conf/viewvc.conf{.dist,}
-	mv conf/cvsgraph.conf{.dist,}
-
-	python_convert_shebangs -r 2 .
-}
-
-src_install() {
-	webapp_src_preinst
-
-	newbin bin/standalone.py viewvc-standalone-server
-
-	dodoc CHANGES COMMITTERS INSTALL README
-
-	installation() {
-		insinto $(python_get_sitedir)/${PN}
-		doins -r lib/*
-	}
-	python_execute_function installation
-
-	insinto "${MY_APPDIR}"
-	doins -r templates/ || die "doins failed"
-	doins -r templates-contrib/
-
-	if use mysql; then
-		exeinto "${MY_HOSTROOTDIR}/bin"
-		doexe bin/{*dbadmin,make-database,loginfo-handler}
-	fi
-
-	insinto "${MY_HOSTROOTDIR}/conf"
-	doins conf/{viewvc,cvsgraph}.conf
-
-	exeinto "${MY_CGIBINDIR}"
-	doexe bin/cgi/viewvc.cgi
-	if use mysql; then
-		doexe bin/cgi/query.cgi
-	fi
-
-	exeinto "${MY_CGIBINDIR}"
-	if use mod_wsgi; then
-		doexe bin/wsgi/viewvc.wsgi
-		if use mysql; then
-			doexe bin/wsgi/query.wsgi
-		fi
-	else
-		doexe bin/wsgi/viewvc.fcgi
-		if use mysql; then
-			doexe bin/wsgi/query.fcgi
-		fi
-	fi
-
-	webapp_configfile "${MY_HOSTROOTDIR}/conf/"{viewvc,cvsgraph}.conf
-
-	webapp_src_install
-}
-
-pkg_postinst() {
-	python_mod_optimize viewvc
-	webapp_pkg_postinst
-	elog "Now read INSTALL in /usr/share/doc/${PF} to configure ${PN}"
-}
-
-pkg_postrm() {
-	python_mod_cleanup viewvc
-}
-- 
cgit v1.2.3-65-gdbad