From 9a553d0adf1bb9bae727fb27efbcbaab0d57a30e Mon Sep 17 00:00:00 2001
From: Andrey Grozin <grozin@gentoo.org>
Date: Sat, 14 Jan 2023 19:13:01 +0700
Subject: sci-mathematics/form: bump to 4.3.0

Signed-off-by: Andrey Grozin <grozin@gentoo.org>
---
 sci-mathematics/form/Manifest          |  1 +
 sci-mathematics/form/form-4.3.0.ebuild | 81 ++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 sci-mathematics/form/form-4.3.0.ebuild

diff --git a/sci-mathematics/form/Manifest b/sci-mathematics/form/Manifest
index 2901a66f405d..05d5cb206104 100644
--- a/sci-mathematics/form/Manifest
+++ b/sci-mathematics/form/Manifest
@@ -1 +1,2 @@
 DIST form-4.2.1.tar.gz 1444257 BLAKE2B 27ac9ee1412e6f478324b170e37e6e31822b74f902a5739d5fa00558aa4c9f7a977bd5fe3d6982313f1232a774c592d44af07fec8a290266c31bf3a100e87d1a SHA512 5569ae3e487194b0d082f4a032fb4b8d57238218d92d9b04d5f51db2a73e065eb1efdc26011bda46723e902fa3f324010ca2f8e91ba9a077e87b0a07b40cf594
+DIST form-4.3.0.tar.gz 1457721 BLAKE2B 029c62b0e1d92cf66be0290e45467e9de47f8ac9a593e7d012c13d877fb84aa1a212bb99b7a1a7b8b5b04c4cb056b58da80812faf5f0af5d33629c7632768ae6 SHA512 3f7f9cabf37d33fce0dcb7e091ac5ce60412ebe840fcea432655ab7f0c86c620200d60df085af3011d92d8057d9501583f16686257e5d097f6d0571d7f1b6742
diff --git a/sci-mathematics/form/form-4.3.0.ebuild b/sci-mathematics/form/form-4.3.0.ebuild
new file mode 100644
index 000000000000..42e130cd9849
--- /dev/null
+++ b/sci-mathematics/form/form-4.3.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Symbolic Manipulation System"
+HOMEPAGE="https://www.nikhef.nl/~form/ https://github.com/vermaseren/form/"
+SRC_URI="https://github.com/vermaseren/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="devref doc doxygen gmp mpi threads zlib"
+
+RDEPEND="
+	gmp? ( dev-libs/gmp:0= )
+	mpi? ( virtual/mpi )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	devref? ( dev-texlive/texlive-latex )
+	doc? ( dev-texlive/texlive-latex )
+	doxygen? ( app-doc/doxygen )"
+
+src_prepare() {
+	default
+	sed -i 's/LINKFLAGS = -s/LINKFLAGS =/' sources/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-scalar \
+		--enable-largefile \
+		--disable-debug \
+		--disable-static-link \
+		--with-api=posix \
+		$(use_with gmp ) \
+		$(use_enable mpi parform ) \
+		$(use_enable threads threaded ) \
+		$(use_with zlib ) \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		CXXFLAGS="${CXXFLAGS}"
+}
+
+src_compile() {
+	default
+	if use devref; then
+		pushd doc/devref > /dev/null || die "doc/devref does not exist"
+		LANG=C emake pdf
+		popd > /dev/null
+	fi
+	if use doc; then
+		pushd doc/manual > /dev/null || die "doc/manual does not exist"
+		LANG=C emake pdf
+		popd > /dev/null
+	fi
+	if use doxygen; then
+		pushd doc/doxygen > /dev/null || die "doc/doxygen does not exist"
+		emake html
+		popd > /dev/null
+	fi
+}
+
+src_install() {
+	default
+	if use devref; then
+		dodoc doc/devref/devref.pdf
+	fi
+	if use doc; then
+		dodoc doc/manual/manual.pdf
+	fi
+	if use doxygen; then
+		docinto html
+		dodoc -r doc/doxygen/html/.
+	fi
+}
-- 
cgit v1.2.3-65-gdbad