From 09978a4d6fbfd46071119b15a167db69edc541a8 Mon Sep 17 00:00:00 2001
From: Alfred Wingate <parona@protonmail.com>
Date: Sat, 19 Feb 2022 13:58:10 +0200
Subject: gui-apps/grim: update dependencies and install completions manually

* Disable bash-completions switch and instead install bash completions
  with bash-completion-r1 eclass.
* This serves to avoid the build system requiring
  app-shells/bash-completion or having to go out of your way to remove
  this requirement from the build system itself.
* Install fish completions manually with doins.
* These changes are included in a new revision of 1.4.0 and in 9999.

* Also update EAPI to 8 and update dependencies.

Closes: https://bugs.gentoo.org/833595
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Closes: https://github.com/gentoo/gentoo/pull/24273
Signed-off-by: Sam James <sam@gentoo.org>
---
 gui-apps/grim/grim-1.4.0-r1.ebuild | 50 ++++++++++++++++++++++++++++++++++++++
 gui-apps/grim/grim-1.4.0.ebuild    | 46 -----------------------------------
 gui-apps/grim/grim-9999.ebuild     | 28 ++++++++++++---------
 3 files changed, 67 insertions(+), 57 deletions(-)
 create mode 100644 gui-apps/grim/grim-1.4.0-r1.ebuild
 delete mode 100644 gui-apps/grim/grim-1.4.0.ebuild

diff --git a/gui-apps/grim/grim-1.4.0-r1.ebuild b/gui-apps/grim/grim-1.4.0-r1.ebuild
new file mode 100644
index 000000000000..66522ea185c3
--- /dev/null
+++ b/gui-apps/grim/grim-1.4.0-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1 meson
+
+DESCRIPTION="Grab images from a Wayland compositor"
+HOMEPAGE="https://github.com/emersion/grim"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/emersion/${PN}.git"
+else
+	SRC_URI="https://github.com/emersion/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="+man jpeg"
+
+DEPEND="
+	>=dev-libs/wayland-protocols-1.14
+	dev-libs/wayland
+	media-libs/libpng
+	x11-libs/pixman
+	jpeg? ( virtual/jpeg )"
+
+RDEPEND="${DEPEND}"
+BDEPEND="man? ( app-text/scdoc )"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature jpeg)
+		$(meson_feature man man-pages)
+		"-Dbash-completions=false"
+		"-Dfish-completions=false"
+		"-Dwerror=false"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	newbashcomp contrib/completions/bash/grim.bash grim
+	insinto /usr/share/fish/vendor_completions.d/
+	doins contrib/completions/grim.fish
+}
diff --git a/gui-apps/grim/grim-1.4.0.ebuild b/gui-apps/grim/grim-1.4.0.ebuild
deleted file mode 100644
index 3b5657ccc9d2..000000000000
--- a/gui-apps/grim/grim-1.4.0.ebuild
+++ /dev/null
@@ -1,46 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit meson
-
-DESCRIPTION="Grab images from a Wayland compositor"
-HOMEPAGE="https://github.com/emersion/grim"
-
-if [[ ${PV} == 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/emersion/${PN}.git"
-else
-	SRC_URI="https://github.com/emersion/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm64"
-fi
-
-LICENSE="MIT"
-SLOT="0"
-IUSE="+man jpeg"
-
-DEPEND="
-	>=dev-libs/wayland-protocols-1.14
-	dev-libs/wayland
-	jpeg? ( virtual/jpeg )
-	x11-libs/cairo"
-
-RDEPEND="${DEPEND}"
-
-if [[ ${PV} == 9999 ]]; then
-	BDEPEND+="man? ( ~app-text/scdoc-9999 )"
-else
-	BDEPEND+="man? ( app-text/scdoc )"
-fi
-
-src_configure() {
-	local emesonargs=(
-		$(meson_feature jpeg)
-		$(meson_feature man man-pages)
-		"-Dwerror=false"
-		"-Dfish-completions=true"
-		"-Dbash-completions=true"
-	)
-	meson_src_configure
-}
diff --git a/gui-apps/grim/grim-9999.ebuild b/gui-apps/grim/grim-9999.ebuild
index ca7406fc07a3..66522ea185c3 100644
--- a/gui-apps/grim/grim-9999.ebuild
+++ b/gui-apps/grim/grim-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-inherit meson
+inherit bash-completion-r1 meson
 
 DESCRIPTION="Grab images from a Wayland compositor"
 HOMEPAGE="https://github.com/emersion/grim"
@@ -23,22 +23,28 @@ IUSE="+man jpeg"
 DEPEND="
 	>=dev-libs/wayland-protocols-1.14
 	dev-libs/wayland
-	jpeg? ( virtual/jpeg )
-	x11-libs/cairo"
+	media-libs/libpng
+	x11-libs/pixman
+	jpeg? ( virtual/jpeg )"
 
 RDEPEND="${DEPEND}"
-
-if [[ ${PV} == 9999 ]]; then
-	BDEPEND+="man? ( ~app-text/scdoc-9999 )"
-else
-	BDEPEND+="man? ( app-text/scdoc )"
-fi
+BDEPEND="man? ( app-text/scdoc )"
 
 src_configure() {
 	local emesonargs=(
 		$(meson_feature jpeg)
 		$(meson_feature man man-pages)
+		"-Dbash-completions=false"
+		"-Dfish-completions=false"
 		"-Dwerror=false"
 	)
 	meson_src_configure
 }
+
+src_install() {
+	meson_src_install
+
+	newbashcomp contrib/completions/bash/grim.bash grim
+	insinto /usr/share/fish/vendor_completions.d/
+	doins contrib/completions/grim.fish
+}
-- 
cgit v1.2.3-65-gdbad