1 files changed, 50 insertions, 0 deletions
diff --git a/sci-libs/shapely/shapely-1.8.2.ebuild b/sci-libs/shapely/shapely-1.8.2.ebuild
new file mode 100644
index 000000000000..e123057db79a
--- /dev/null
+++ b/sci-libs/shapely/shapely-1.8.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Geometric objects, predicates, and operations"
+HOMEPAGE="
+	https://pypi.org/project/Shapely/
+	https://github.com/shapely/shapely/
+"
+SRC_URI="
+	https://github.com/shapely/shapely/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="
+	>=sci-libs/geos-3.9
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${DEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs dev-python/matplotlib
+
+src_prepare() {
+	rm -r _vendor || die
+	sed -i -e 's:_vendor\.::' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	rm -rf shapely || die
+	epytest
+}