2 files changed, 64 insertions, 0 deletions
diff --git a/net-wireless/neard/Manifest b/net-wireless/neard/Manifest
index 3cfbeb5c7a82..7be249d4098a 100644
--- a/net-wireless/neard/Manifest
+++ b/net-wireless/neard/Manifest
@@ -1 +1,2 @@
 DIST neard-0.16.tar.xz 379436 BLAKE2B 8432200eafa2d7517d768ef160e2d2f8db698119ea047d505d7212b1c2d46087223b71749a4c855bf7e7ff43f73d4aa6d67fab272909dbb3236b312ee3b911be SHA512 d0fd5dcfd19db64e65e4149c76979bc7a438240aa6840b35059fde41a8a84a2424274577de964a925e76cd013d21796f69f5361012b6ac79c546d0abdcfed2a6
+DIST neard-0.18.tar.gz 228597 BLAKE2B 516205c8731bd1104e10a87408209a1848343078f814753f57fd63bc60e7146974737b13757f490bff83e538744e3d0c5fde9224d1d04ddb901c9d71076749a7 SHA512 2f1da13ade60a75b81e51a76be80a5f6681439c612ae33659eed2e495b1e390dcb1deb60945e14a4bec247b3a046b940146b78925f43be88f35880e4677c721b
diff --git a/net-wireless/neard/neard-0.18.ebuild b/net-wireless/neard/neard-0.18.ebuild
new file mode 100644
index 000000000000..f44a4d6f81fb
--- /dev/null
+++ b/net-wireless/neard/neard-0.18.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Near Field Communication (NFC) management daemon"
+HOMEPAGE="https://github.com/linux-nfc/neard"
+SRC_URI="https://github.com/linux-nfc/neard/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="test tools systemd"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.28
+	dev-libs/libnl:3=
+	>=sys-apps/dbus-1.2
+	systemd? ( sys-apps/systemd:0 )
+"
+
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-optimization
+		--enable-ese
+		--enable-nfctype1
+		--enable-nfctype2
+		--enable-nfctype3
+		--enable-nfctype4
+		--enable-nfctype5
+		--enable-p2p
+		--enable-pie
+		$(use_enable systemd)
+		$(use_enable test)
+		$(use_enable tools)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	# Patch for this has been sent upstream.  Do it manually
+	# to avoid having to rebuild autotools. #580876
+	mv "${ED}/usr/include/version.h" "${ED}/usr/include/near/" || die
+
+	insinto "/etc/dbus-1/system.d/"
+	doins "se/org.neard.se.conf"
+
+	newinitd "${FILESDIR}/neard.rc" neard
+	newconfd "${FILESDIR}/neard.confd" neard
+}