2 files changed, 82 insertions, 0 deletions
diff --git a/media-sound/gnome-music/Manifest b/media-sound/gnome-music/Manifest
index a73f9fd0915b..0191dafa1223 100644
--- a/media-sound/gnome-music/Manifest
+++ b/media-sound/gnome-music/Manifest
@@ -1 +1,2 @@
 DIST gnome-music-40.1.1.tar.xz 978092 BLAKE2B cf9e41e1d519431c33edbd03eb72565612d127d7f6fd82ca34d46b1b3ed58073b7435d3b5b80b149a5fc47ea549018756914dbef5e512cb036303b64b4882083 SHA512 3095dfd31dc32f831e776055d5c1f8c32af5958be632050f709f5c3991b272769edac09a339638de2accf6aae4bf6e8dd1f377a0136897eade2c21d2ebce5f5e
+DIST gnome-music-41.0.tar.xz 898652 BLAKE2B cc72eb7be553ccefe10620a85aa3ee75aa30c1809e810a8ebb30a2ffbccebb9dc173cc79859e098be97fea9c964f0f6969f55c7c84ea9540a93a920376746ac1 SHA512 883f8862d5216ab30c3208a316378c2ef016ba52861c9261b8fa9ceb44f935e4dc35608ea66b333c3bf61c9dcc950fa338adfadc2d5e7f67a7a84467228d28a2
diff --git a/media-sound/gnome-music/gnome-music-41.0.ebuild b/media-sound/gnome-music/gnome-music-41.0.ebuild
new file mode 100644
index 000000000000..dc330de8c9a2
--- /dev/null
+++ b/media-sound/gnome-music/gnome-music-41.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="Music management for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/Music"
+
+LICENSE="GPL-2+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-libs/glib-2.67.1:2
+	>=net-libs/gnome-online-accounts-3.35.90[introspection]
+	>=dev-libs/gobject-introspection-1.54:=
+	>=x11-libs/gtk+-3.24.14:3[introspection]
+	>=gui-libs/libhandy-1.2.0:1=[introspection]
+	>=dev-libs/libdazzle-3.28.0[introspection]
+	>=media-libs/libmediaart-1.9.1:2.0[introspection]
+	net-libs/libsoup:2.4[introspection]
+	app-misc/tracker:3=[introspection(+)]
+	>=x11-libs/pango-1.44:=
+	$(python_gen_cond_dep '
+		>=dev-python/pygobject-3.36.1:3[cairo,${PYTHON_USEDEP}]
+		>=dev-python/pycairo-1.14.0[${PYTHON_USEDEP}]
+	')
+	>=media-libs/grilo-0.3.13:0.3[introspection]
+	>=media-plugins/grilo-plugins-0.3.13:0.3
+"
+# xdg-user-dirs-update needs to be there to create needed dirs
+# https://bugzilla.gnome.org/show_bug.cgi?id=731613
+RDEPEND="${DEPEND}
+	|| (
+		app-misc/tracker-miners:3[gstreamer]
+		app-misc/tracker-miners:3[ffmpeg]
+	)
+	x11-libs/libnotify[introspection]
+	media-libs/gstreamer:1.0[introspection]
+	media-libs/gst-plugins-base:1.0[introspection]
+	media-plugins/gst-plugins-meta:1.0
+	media-plugins/grilo-plugins:0.3[tracker]
+	x11-misc/xdg-user-dirs
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/40.1.1-fix-build-with-meson-0.61.1.patch
+)
+
+RESTRICT="test" # only does desktop and appdata validation, and latter needs network to validate screenshot from https
+
+pkg_setup() {
+	python_setup
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${D}"/usr/bin/gnome-music
+	python_optimize
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}