1 files changed, 55 insertions, 0 deletions
diff --git a/kde-plasma/breeze/breeze-5.19.0.ebuild b/kde-plasma/breeze/breeze-5.19.0.ebuild
new file mode 100644
index 000000000000..56328803f8d8
--- /dev/null
+++ b/kde-plasma/breeze/breeze-5.19.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+inherit ecm kde.org
+
+DESCRIPTION="Breeze visual style for the Plasma desktop"
+HOMEPAGE="https://invent.kde.org/plasma/breeze"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64"
+IUSE="wayland X"
+
+RDEPEND="
+	>=kde-frameworks/frameworkintegration-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/kdecoration-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	sci-libs/fftw:3.0=
+	wayland? ( >=kde-frameworks/kwayland-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/kpackage-${KFMIN}:5
+"
+PDEPEND="
+	>=kde-frameworks/breeze-icons-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package wayland KF5Wayland)
+		$(cmake_use_find_package X XCB)
+	)
+	ecm_src_configure
+}