1 files changed, 41 insertions, 0 deletions
diff --git a/dev-perl/Gtk2-Notify/Gtk2-Notify-0.50.0-r1.ebuild b/dev-perl/Gtk2-Notify/Gtk2-Notify-0.50.0-r1.ebuild
new file mode 100644
index 000000000000..a04edfd70747
--- /dev/null
+++ b/dev-perl/Gtk2-Notify/Gtk2-Notify-0.50.0-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DIST_AUTHOR=FLORA
+DIST_VERSION=0.05
+inherit perl-module virtualx
+
+DESCRIPTION="A perl interface to the notification library"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+
+RDEPEND="
+	dev-perl/glib-perl
+	dev-perl/Gtk2
+	>=x11-libs/libnotify-0.7
+"
+BDEPEND="${RDEPEND}
+	dev-perl/ExtUtils-Depends
+	dev-perl/ExtUtils-PkgConfig
+	test? ( dev-perl/Test-Exception )
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.05-libnotify.patch )
+
+PERL_RM_FILES=( t/notification.t )
+# the test dies if no notification daemon is present...
+
+src_prepare() {
+	sed -i -e 's/use inc::Module::Install;/use lib q[.]; use inc::Module::Install;/' Makefile.PL ||
+		die "Can't patch Makefile.PL for 5.26 dot-in-inc"
+	perl-module_src_prepare
+}
+
+src_test() {
+	# bug 416729
+	virtx perl-module_src_test
+}