1 files changed, 43 insertions, 0 deletions
diff --git a/dev-libs/libburn/libburn-1.4.6.ebuild b/dev-libs/libburn/libburn-1.4.6.ebuild
new file mode 100644
index 000000000000..39235de81756
--- /dev/null
+++ b/dev-libs/libburn/libburn-1.4.6.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils
+
+DESCRIPTION="Open-source library for reading, mastering and writing optical discs"
+HOMEPAGE="http://libburnia-project.org"
+SRC_URI="http://files.libburnia-project.org/releases/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="cdio debug static-libs track-src-odirect"
+
+RDEPEND="cdio? ( >=dev-libs/libcdio-0.83 )"
+DEPEND="$RDEPEND
+	virtual/pkgconfig"
+
+src_configure() {
+	econf \
+	$(use_enable static-libs static) \
+	$(use_enable track-src-odirect) \
+	--enable-pkg-check-modules \
+	$(use_enable cdio libcdio) \
+	--disable-ldconfig-at-install \
+	$(use_enable debug)
+}
+
+src_install() {
+	default
+
+	dodoc CONTRIBUTORS doc/{comments,*.txt}
+
+	docinto cdrskin
+	dodoc cdrskin/{*.txt,README}
+	docinto cdrskin/html
+	dodoc cdrskin/cdrskin_eng.html
+
+	prune_libtool_files --all
+}