1 files changed, 79 insertions, 0 deletions
diff --git a/dev-embedded/libftdi/libftdi-0.20-r1.ebuild b/dev-embedded/libftdi/libftdi-0.20-r1.ebuild
new file mode 100644
index 000000000000..26f83972b5de
--- /dev/null
+++ b/dev-embedded/libftdi/libftdi-0.20-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_4 python3_5 python3_6 )
+inherit cmake-utils python-single-r1
+
+if [[ ${PV} == 9999* ]] ; then
+	EGIT_REPO_URI="git://developer.intra2net.com/${PN}"
+	inherit git-2
+else
+	SRC_URI="http://www.intra2net.com/en/developer/${PN}/download/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+DESCRIPTION="Userspace access to FTDI USB interface chips"
+HOMEPAGE="http://www.intra2net.com/en/developer/libftdi/"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="cxx doc examples python"
+
+RDEPEND="virtual/libusb:0
+	cxx? ( dev-libs/boost )
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	python? ( dev-lang/swig )
+	doc? ( app-doc/doxygen )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	if use python; then
+		sed -i \
+			-e "s:[$]{PYTHON_LIB_INSTALL}/../site-packages:$(python_get_sitedir):" \
+			bindings/CMakeLists.txt || die
+	fi
+	sed -i \
+		-e '/SET(LIB_SUFFIX /d' \
+		CMakeLists.txt || die
+
+	eapply "${FILESDIR}"/${P}-cmake-{include,version}.patch
+	eapply_user
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DFTDIPP=$(usex cxx)
+		-DDOCUMENTATION=$(usex doc)
+		-DEXAMPLES=$(usex examples)
+		-DPYTHON_BINDINGS=$(usex python)
+		-DCMAKE_SKIP_BUILD_RPATH=ON
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	use python && python_optimize
+	dodoc ChangeLog README
+
+	if use doc ; then
+		# Clean up crap man pages. #356369
+		rm -vf "${CMAKE_BUILD_DIR}"/doc/man/man3/{_,usb_,deprecated}*
+
+		doman "${CMAKE_BUILD_DIR}"/doc/man/man3/*
+		dodoc -r "${CMAKE_BUILD_DIR}"/doc/html
+	fi
+	if use examples ; then
+		docinto examples
+		dodoc examples/*.c
+	fi
+}