1 files changed, 45 insertions, 0 deletions
diff --git a/app-admin/watchfolder/watchfolder-0.3.3-r2.ebuild b/app-admin/watchfolder/watchfolder-0.3.3-r2.ebuild
new file mode 100644
index 000000000000..9a93d1579f8a
--- /dev/null
+++ b/app-admin/watchfolder/watchfolder-0.3.3-r2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Watches directories and processes files"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+S="${WORKDIR}/${P/folder/d}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~ppc ~x86"
+
+PATCHES=(
+	# patch to remove warnings on 64 bit systems
+	"${FILESDIR}"/${PV}-64bit.patch
+	# and a gcc 4.3.3 / fortify_sources fix
+	"${FILESDIR}"/${PV}-fortify-sources.patch
+	# various implicit declarations
+	"${FILESDIR}"/${PV}-implicit-decl.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/-c -o/s:OPT:CFLAGS:' \
+		-e 's:(\(LD\)\?OPT):(LDFLAGS) $(CFLAGS):' \
+		-e 's:gcc:$(CC):' \
+		Makefile || die "sed Makefile failed"
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	dobin watchd
+	insinto /etc
+	doins watchd.conf
+	dodoc README doc/*
+}