1 files changed, 0 insertions, 114 deletions
diff --git a/app-admin/abrt/abrt-2.10.9.ebuild b/app-admin/abrt/abrt-2.10.9.ebuild
deleted file mode 100644
index 313aab7271b3..000000000000
--- a/app-admin/abrt/abrt-2.10.9.ebuild
+++ /dev/null
@@ -1,114 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python3_{4,5,6} )
-
-inherit autotools gnome2-utils python-single-r1 systemd user
-
-DESCRIPTION="Automatic bug detection and reporting tool"
-HOMEPAGE="https://github.com/abrt/abrt/wiki/ABRT-Project"
-SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="debug selinux"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-COMMON_DEPEND="${PYTHON_DEPS}
-	>=dev-libs/glib-2.43:2
-	>=dev-libs/libreport-2.9.5[python]
-	dev-libs/libxml2
-	dev-libs/nss
-	>=gnome-base/gsettings-desktop-schemas-3.15.1
-	sys-apps/dbus
-	sys-apps/systemd
-	sys-auth/polkit
-	sys-fs/inotify-tools
-	x11-libs/gtk+:3
-	>=x11-libs/libnotify-0.7"
-RDEPEND="${COMMON_DEPEND}
-	app-arch/cpio
-	dev-libs/elfutils
-	dev-python/argcomplete
-	dev-python/argh
-	dev-python/humanize
-	sys-apps/util-linux
-	>=sys-devel/gdb-7"
-DEPEND="${COMMON_DEPEND}
-	app-text/asciidoc
-	app-text/xmlto
-	dev-libs/satyr[${PYTHON_USEDEP}]
-	>=dev-util/intltool-0.35.0
-	virtual/pkgconfig
-	>=sys-devel/gettext-0.17"
-
-REQUIRED_USE=${PYTHON_REQUIRED_USE}
-
-RESTRICT="test" # tests *may* be broken due to all the RHEL crap.  explore later.
-
-pkg_setup() {
-	python-single-r1_pkg_setup
-
-	enewgroup abrt
-	enewuser abrt -1 -1 -1 abrt
-}
-
-src_prepare() {
-	default
-
-	# pyhook test is sensitive to the format of python's error messages, and
-	# fails with certain python versions
-	sed -e '/pyhook.at/ d' \
-		-i tests/Makefile.* tests/testsuite.at || die "sed remove pyhook tests failed"
-	./gen-version || die # Needed to be run before autoreconf
-	eautoreconf
-}
-
-src_configure() {
-
-	myeconfargs=(
-		--libdir="${EPREFIX}/$(get_libdir)"
-		--localstatedir="${EPREFIX}/var"
-		--without-bodhi
-		# package breaks due to not finding libreport-web with bodhi plugin enabled
-		--without-rpm
-		$(usex selinux "" "--without-selinux")
-		--without-python2
-		# Fixes "syntax error in VERSION script" and we aren't supporting Python2 anyway
-		--with-python3
-		--without-pythondoc
-		# package breaks due to no sphinx-build-3
-		--without-pythontests
-		# kill tests for now until they can be explored.
-	)
-	econf "${myeconfargs[@]}"
-}
-
-src_install() {
-	default
-
-	keepdir /var/run/abrt
-	# /var/spool/abrt is created by dev-libs/libreport
-
-	diropts -m 700 -o abrt -g abrt
-	keepdir /var/spool/abrt-upload
-
-	diropts -m 775 -o abrt -g abrt
-	keepdir /var/cache/abrt-di
-
-	find "${D}" -name '*.la' -exec rm -f {} + || die
-
-	newinitd "${FILESDIR}/${PN}-2.0.12-r1-init" abrt
-	newconfd "${FILESDIR}/${PN}-2.0.12-r1-conf" abrt
-}
-
-pkg_postinst() {
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	gnome2_icon_cache_update
-}