x11-terms/terminology: update to reflect efl[gles2-only]

Bug: https://bugs.gentoo.org/728306
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/x11-terms/terminology/terminology-1.7.0-r1.ebuild b/x11-terms/terminology/terminology-1.7.0-r1.ebuild
new file mode 100644
index 000000000000..6b3a9662a1c8
--- /dev/null
+++ b/x11-terms/terminology/terminology-1.7.0-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg-utils
+
+DESCRIPTION="Feature rich terminal emulator using the Enlightenment Foundation Libraries"
+HOMEPAGE="https://www.enlightenment.org/about-terminology"
+SRC_URI="https://download.enlightenment.org/rel/apps/${PN}/${P}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~ppc ~ppc64 x86"
+IUSE="extras nls"
+
+RDEPEND="|| (
+		|| (
+			>=dev-libs/efl-1.24.3[gles2-only]
+			<dev-libs/efl-1.24.3[gles2]
+		)
+		dev-libs/efl[opengl]
+	)
+	|| ( dev-libs/efl[X] dev-libs/efl[wayland] )
+	app-arch/lz4
+	dev-libs/efl[eet,fontconfig]"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use nls)
+		$(meson_use extras tests)
+	)
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}