www-apps/Apache-Gallery: update EAPI 5 -> 7

Closes: https://bugs.gentoo.org/835356
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 57 insertions, 0 deletions

diff --git a/www-apps/Apache-Gallery/Apache-Gallery-1.0_rc3-r2.ebuild b/www-apps/Apache-Gallery/Apache-Gallery-1.0_rc3-r2.ebuild
new file mode 100644
index 000000000000..2489658f8280
--- /dev/null
+++ b/www-apps/Apache-Gallery/Apache-Gallery-1.0_rc3-r2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit depend.apache perl-module webapp
+
+MY_P=${P/_rc/RC}
+
+DESCRIPTION="Apache gallery for mod_perl"
+HOMEPAGE="http://apachegallery.dk/"
+SRC_URI="http://apachegallery.dk/download/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="|| ( Artistic GPL-2 )"
+SLOT="0"
+KEYWORDS="amd64 ppc x86"
+
+WEBAPP_MANUAL_SLOT="yes"
+
+RDEPEND="
+	=dev-lang/perl-5*
+	=www-apache/libapreq2-2*[perl]
+	>=media-libs/imlib2-1.0.6-r1
+	dev-perl/URI
+	>=dev-perl/Image-Info-1.40.0
+	>=dev-perl/Image-Size-2.990.0
+	dev-perl/Text-Template
+	>=dev-perl/CGI-3.08
+	dev-perl/Image-Imlib2"
+
+need_apache2
+
+src_install() {
+	perl-module_src_install
+	webapp_src_preinst
+
+	dodoc Changes INSTALL README TODO UPGRADE
+
+	insinto "${MY_ICONSDIR}"/gallery
+	doins htdocs/*.png
+
+	dodir "${MY_HOSTROOTDIR}"/${PN}/templates/default
+	dodir "${MY_HOSTROOTDIR}"/${PN}/templates/new
+
+	insinto "${MY_HOSTROOTDIR}"/${PN}/templates/default
+	doins templates/default/*
+
+	insinto "${MY_HOSTROOTDIR}"/${PN}/templates/new
+	doins templates/new/*
+
+	insinto "${APACHE_VHOSTS_CONFDIR}"
+	doins "${FILESDIR}"/76_apache2-gallery.conf
+
+	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
+	webapp_src_install
+}