sys-kernel/gentoo-kernel-bin: Bump to 5.4.242-r2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 129 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 081c0db4fa46..a0994f32d1a1 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -18,6 +18,8 @@ DIST genpatches-5.4-246.base.tar.xz 5659072 BLAKE2B 4b3f836c7e9f7f4d1cac0c735bbb
 DIST genpatches-5.4-246.extras.tar.xz 1812 BLAKE2B 78297c82519cf71230dc19d674d345cb40d8226adab6af53c0c3af7239f7a1464b8c89b51b62c509b33e8b2eb1a8c102b10146a8a6151ab5f069a1e00f8f6f8c SHA512 13aa1321f559e01257926ef94dd023222c2be9225bb412424a4b4696c1e6d6abe3e7f29c375836e1f9986d496df89051a60c34e8f8070aa0bd556683a387e356
 DIST genpatches-5.4-248.base.tar.xz 5689960 BLAKE2B 50714236c3fa565fb097577d8885ea6b0f6448061025221c317df2270877f70093446a79c60baa8247a80a481ee2475720836651cf2a83c31b13e0a59e6e30ed SHA512 0850c79fe4bbb6752e2a9a316204638287107b72ed180d0f417b6d03fd9288305a221d1e085bc4da0fe7ed82790e29525bee72c288f5e6d876c306ef316f8d82
 DIST genpatches-5.4-248.extras.tar.xz 1812 BLAKE2B 2e95caa558cb93ee161cb9c83f7a5b403539253c1c74f4b3f1d7433b96c5100504d132bde1d2f1d4d790061720c29fc4c77cafcf0cb4ca80ee8a8826db076670 SHA512 194f2797181812b13e25755bb9413821790d953029e322ca5e24c534df56a0fe094ec005e50a761d3968f68d5c9502b27a47c87fc3276472db900f856708abe4
+DIST genpatches-5.4-249.base.tar.xz 5692112 BLAKE2B 8057ddb24ebbd5ee1b4fb5f5a36b295c4e8ab857e407c5b9e061780e1d23ecca7ab5adfb10ca4f6733a7776c2aa6e353419257c255b07bc991ecb6857aa31555 SHA512 b0057da850ab5368dcbf2b454d408b72204150cc2643e087d2f084c3074de22ce36fa4c319552b90d9059ba279e8dc6551cd6348c3616275b050167bfdb58023
+DIST genpatches-5.4-249.extras.tar.xz 1812 BLAKE2B b6b7bccf77851a17e8b514439a50c44de954ff461af71414c325ca5c0a65d7a79ee92f7a8b708afd28a3433acddd13aa3bbd5afcd82b4181e57ea05b008d7090 SHA512 c4977abc2bbb1c2319e9d2e4aed38419f9e2a70813e5f28d2b799533fc945574d9fee21c881b6dd4926a9c2ebe74ae414ada4993e3fcbd117b6536f983533282
 DIST genpatches-6.1-28.base.tar.xz 1412456 BLAKE2B 126c74e7558efbfb104e97e993a70b628fe7882d756ef0ef29031b042651a8df3e2e940d31f85556453cd391358421594f9e089ed194e14b107932a8d525ddf2 SHA512 b033d8b873b0c8ebdd89b25dd25a814746b1debc0f0944da8fdc2ec9ed1da3d8d45816547119f7548ac30a91003c3c078a193875711d7839e4de71234192ac6d
 DIST genpatches-6.1-28.extras.tar.xz 3808 BLAKE2B 3bd49fb256420883a267b2513cc9e6928a107b0142c82d9abd20114f733bfcbd474eeb19a7ef833da27ba625db28806ec25a1dd945f5d94f5bd5f729e445a57d SHA512 06c84adf52e36357fd01e8e1989ba8b8cb08bef052da05d261df3e80aac6d2d10a3c39583fad6d92936e19d8c7484786a4d11f64f2dc3fb5f8e1ee90106d6367
 DIST genpatches-6.1-30.base.tar.xz 1467496 BLAKE2B 7e442668319addb39f4812669463c312c9cda5095c1086732da3ba39eb9836985e53afeba31f471d6cd2774d6028e421a254721bcae10ef89d6d38f3856debde SHA512 90a3309cc2e6cad1a971c864839e6acdedb10986fbbfb89799d1327fd4c9a541f4a46aa4d5a898046d1e0a0a648547717e522ee31622ded87e48ec4057a49dc0
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.242-r2.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.242-r2.ebuild
new file mode 100644
index 000000000000..70e2f755ed95
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.242-r2.ebuild
@@ -0,0 +1,127 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit kernel-install toolchain-funcs unpacker
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 7 ))
+BINPKG=${P/-bin}-1
+
+DESCRIPTION="Pre-built Linux kernel with Gentoo patches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	amd64? (
+		https://dev.gentoo.org/~mgorny/binpkg/amd64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.amd64.gpkg.tar
+	)
+	arm64? (
+		https://dev.gentoo.org/~mgorny/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.arm64.gpkg.tar
+	)
+	ppc64? (
+		https://dev.gentoo.org/~mgorny/binpkg/ppc64le/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.ppc64le.gpkg.tar
+	)
+	x86? (
+		https://dev.gentoo.org/~mgorny/binpkg/x86/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.x86.gpkg.tar
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}
+"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	app-alternatives/yacc
+"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH="$(tc-arch-kernel)"
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "${BINPKG}/image/usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/${BINPKG}/image/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"${BINPKG}/image/lib/modules/${KPV}"
+}
+
+src_install() {
+	mv "${BINPKG}"/image/{lib,usr} "${ED}"/ || die
+
+	# FIXME: requires proper mount-boot
+	if [[ -d ${BINPKG}/image/boot/dtbs ]]; then
+		mv "${BINPKG}"/image/boot "${ED}"/ || die
+	fi
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}