net-misc/youtube-dl: Version 2019.10.29

Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 98e87a211057..11970580f92c 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1 +1,2 @@
 DIST youtube-dl-2019.10.22.tar.gz 3176020 BLAKE2B 4b72273eec5252cd3950d13dcd799924c8cea121e654e43532b2912198b3777903e94776758995e56f49c1c5d782ec9f440f5890a6cde3451e7b62ab731f196d SHA512 02199f67ca52cb55638e8013583b414727345c410cf3078c9bad08aabc544ba830b43ddf75c8cfd87f1db4da5544866576836ae45427c7cfb9c563c86f74a8eb
+DIST youtube-dl-2019.10.29.tar.gz 3172150 BLAKE2B 2cdaed88f1518245515d3d4030db8dd22b83ad1955bbd08fcef52b581d35f2de28dd9a95aafaede4edcba67aaf3b6e7697142ed6c715754da957a5cf8476cf80 SHA512 53d79440a86a08c39ec2f6d26e54aec12594b41419aeba2494eab087b49de97485beaeabc17cf819024799cf6f44d2386422c9d8f484c091c34b8cb202023c9d
diff --git a/net-misc/youtube-dl/youtube-dl-2019.10.29.ebuild b/net-misc/youtube-dl/youtube-dl-2019.10.29.ebuild
new file mode 100644
index 000000000000..89ac8f636eea
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2019.10.29.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{2_7,3_5,3_6,3_7})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+RESTRICT="test"
+SLOT="0"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	|| (
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+	)
+"
+S="${WORKDIR}/${PN}"
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}